Retro1.org codex

*DECK NTCNTAN 
USETEXT NIPDEF
USETEXT AHEADER 
USETEXT LLCB
USETEXT NCNB
USETEXT PARAMS
USETEXT SUPMSG
 
PRGM NTCNTAN; 
STARTIMS; 
 #
*1DC  NTCNTAN 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        NTCNTAN             C. BITTNER          82/02/01 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        SEND TCN/TA/N TO CCP 
* 
*     3. METHOD USED
*        ALLOCATE BUFFER FOR MESSAGE
*        SET UP TCN/TA/N MESSAGE
*        LINK MESSAGE ON PIP OUTBOUND CHAIN 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - NCNB ADDRESS 
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF          AHEADER          LLCB
*        NCNB            PARAMS           SUPMSG
*        OSSIZE 
* 
*     7. ROUTINES CALLED
*        LOCLLCB - LOCATE LLCB
*        MGETS - ALLOCATE EMTPY BUFFER
*        NFOB - LINK MESSAGE ON PIP OUTBOUND CHAIN
*        XTRACE - RECORD PROCEDURE CALL 
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS OVERLAY IS CALLED BY NCSTTP.
*        W A R N I N G - THIS PROGRAM CANNOT EXCEED THE SECONDARY 
*CALL OSSIZE
* 
 #
STOPIMS;
# 
      EXTERNAL VARIABLES
# 
 XREF 
   BEGIN
   PROC LOCLLCB;             # LOCATE LLCB                             #
   PROC MGETS;               # ALLOCATE EMPTY BUFFER                   #
   PROC NFOB;                # LINK MSG ON PIP OUTBOUND CHAIN          #
   PROC XTRACE;              # RECORD PROCEDURE CALL                   #
   LABEL RJMAIN;             # RETURN ADDRESS IN OVLCALL               #
   END
# 
      INTERNAL VARIABLES
# 
      ITEM BUFADDR;          # SM BUFFER ADDRESS                       #
 
#**********************************************************************#
 
      BEGIN 
 
      CONTROL IFEQ DEBUG,1; 
        XTRACE("CNTAN");
      CONTROL FI; 
 
#  GET BUFFER TO HOLD TCN/TA/N                                         #
 
      MGETS(NTCN  + BLKHSIZE + ABHSIZE,BUFADDR,TRUE); 
 
      P<AHEADER> = BUFADDR + BLKHSIZE;
      ABHABT[0] = APPCMD;    # BLOCK TYPE                              #
      ABHACT[0] = CT8ASCII;  # CHARACTER TYPE                          #
      ABHTLC[0] = LTCNN;     # LENGTH OF TCN/TA/N                      #
 
#  SET UP TCN/TA/N                                                     #
 
      P<SUPMSG> = BUFADDR + BLKHSIZE + ABHSIZE; 
      PFCSFC[0] = TCNTAN; 
      RB[0] = TRUE;          # SET NORMAL RESPONSE BIT                 #
      P<SMNIP> = P<SUPMSG>;  # BASE TCN/TA                             #
      P<NCNB> = PARAMS1;
      TCNCN[0] = NCNBCN[0]; 
 
#  LINK MESSAGE ON PIP OUTBOUND CHAIN                                  #
 
      LOCLLCB(NCNBHN[0],NCNBTN[0],P<LLCB>); 
      NFOB(BUFADDR,P<LLCB>);
      GOTO RJMAIN;
      END 
TERM