Retro1.org codex

*DECK STPNERR 
USETEXT NIPDEF
USETEXT PARAMS
PRGM STPNERR; 
STARTIMS; 
 #
*1DC  STPNERR 
* 
*     1. PROC NAME           AUTHOR              DATE 
*        STPNERR             C. BITTNER          81/07/30 
* 
*     2. FUNCTIONAL DESCRIPTION 
*        ISSUE ERROR MESSAGE FOR AN ILLEGAL STATE TABLE 
*        TRIGGER ON THE NETWORK SIDE. 
* 
*     3. METHOD USED
*        FORMAT THE ERROR MESSAGE 
*        CONVERT THE INFORMATION TO THE PROPER DISPLAY FORMAT 
*        CALL ROUTINE OMSG TO DAYFILE THE ERROR MESSAGE 
* 
*     4. ENTRY PARAMETERS 
*        PARAMS1 - HOST NODE
*        PARAMS2 - TERMINAL NODE
*        PARAMS3 - NETWORK CONNECTION NUMBER
*        PARAMS4 - TRIGGER NUMBER 
*        PARAMS6 - NAME OF STATE TABLE PROCESSOR
*        PARAMS7 - CURRENT STATE
* 
*     5. EXIT PARAMETERS
*        NONE 
* 
*     6. COMDECKS CALLED AND SYMPL TEXTS USED 
*        NIPDEF 
*        PARAMS 
* 
*     7. ROUTINES CALLED
*        OMSG - ISSUE NAM DAYFILE MESSAGE 
*        XTRACE - RECORD PROCEDURE CALL 
*        XCDD - CONVERT DECIMAL TO DISPLAY
* 
*     8. DAYFILE MESSAGES AND OTHER IMPORTANT INFORMATION 
*        THIS PROGRAM IS A SECONDARY OVERLAY LOADED 
*        BY SUBROUTINE OVLCALL. 
*        THIS PROGRAM IS CALLED BY NBSTTP AND NCSTTP. 
*        W A R N I N G - THIS PROGRAM CANNOT EXCEED THE SECONDARY 
*CALL OSSIZE
* 
 #
STOPIMS;
 
 
      ITEM STPROC     C(6);  # NAME OF STATE TABLE PROCESSOR           #
      ITEM HN;               # HOST NODE                               #
      ITEM TN;               # TERMINAL NODE                           #
      ITEM CN;               # CONNECTION NUMBER                       #
      ITEM TRIG;             # TRIGGER                                 #
      ITEM STATE;            # STATE                                   #
 
      # EXTERNAL VARIABLES   #
 XREF 
   BEGIN
   PROC OMSG;                # ISSUE NAM DAYFILE MESSAGE               #
   PROC XTRACE;              # RECORD PROCEDURE CALL                   #
   FUNC XCDD  C(10);         # CONVERT DECIMAL TO DISPLAY              #
   LABEL RJMAIN;             # RETURN ADDRESS IN OVLCALL               #
   END
 
# INTERNAL VARIABLES         #
      ITEM SCRATCH;          # SCRATCH VARIABLE                        #
 
      ARRAY STPMSGN P(5); 
        BEGIN 
        ITEM ERRMSGN   C(00,00,40) =
                          ["NIP/       ERR HN=  ,TN=   ,CN=   ,  ,  "]; 
        ITEM STPN      C(00,24,06); 
        ITEM HNN       C(01,48,02); 
        ITEM TNN       C(02,24,03); 
        ITEM NCN       C(03,06,03); 
        ITEM TRIGGER   C(03,30,02); 
        ITEM STATEN    C(03,48,02); 
        ITEM ZERO      U(04,00,60) = [0]; 
        END 
 
 
      BEGIN 
 
      CONTROL IFEQ DEBUG,1; 
        XTRACE("STPNE") ; 
      CONTROL FI; 
 
      HN = PARAMS1;          # HOST NODE                               #
      TN = PARAMS2;          # TERMINAL NODE                           #
      CN = PARAMS3;          # NETWORK CONNECTION NUMBER               #
      TRIG = PARAMS4;        # TRIGGER NUMBER                          #
      STPROC = PARAMS6;      # NAME OF STATE TABLE PROCESSOR           #
      STATE = PARAMS7;       # CURRENT STATE                           #
      STPN = STPROC;         # NAME OF STATE TABLE PROCESSOR           #
      SCRATCH = XCDD(HN);    # CONVERT HOST NODE NUM TO DISPLAY        #
      HNN = C<8,2>SCRATCH;
      SCRATCH = XCDD(TN);    # CONVERT TERMINAL NODE NUM TO DISPLAY    #
      TNN = C<7,3>SCRATCH;
      SCRATCH = XCDD(CN);    # CONVERT CON NUM TO DISPLAY              #
      NCN = C<7,3>SCRATCH;
      SCRATCH = XCDD(TRIG);  # CONVERT TRIGGER NUM TO DISPLAY          #
      TRIGGER = C<8,2>SCRATCH;
      SCRATCH = XCDD(STATE); # CONVERT STATE NUM TO DISPLAY            #
      STATEN = C<8,2>SCRATCH; 
      OMSG(STPMSGN,0);         # DAYFILE MESSAGE                       #
      GOTO RJMAIN;           # RETURN TO CALLING PROGRAM               #
      END 
TERM