Retro1.org codex

*DECK XDUMPFL 
USETEXT NIPDEF
USETEXT OVERLAY 
 
 PROC XDUMPFL;               # DUMP NIP FL                             #
 
 STARTIMS;
 STOPIMS; 
 
# 
      EXTERNAL REFERENCES 
# 
      XREF
        BEGIN 
        PROC OMSG;           # DAYFILE MESSAGE                         #
        PROC RDUMP;          # DUMP NIP FL                             #
        FUNC XCOD C(10);     # CONVERT TO OCTAL DISPLAY                #
        END 
# 
      LOCAL VARIABLES 
# 
      ITEM TEMP;             # TEMPORARY                               #
      ARRAY DMSG [0:0] S(3);
        BEGIN 
        ITEM DMSG$TEXT  C(00,00,28) = 
            ["NIP FL DUMP TAKEN -         "]; 
        ITEM DMSG$DN    C(02,00,06); # NIP FL DUMP INDEX               #
        ITEM DMSG$END   U(02,48,12) = [0];
        END 
 
      CONTROL EJECT;
 
      BEGIN # XDUMPFL # 
 
      RDUMP;                 # DUMP NIP FL TO FILE -DUMP-              #
      TEMP = XCOD(DUMPIND);  # CONVERT DUMP INDEX TO OCTAL DISPLAY     #
      DMSG$DN[0] = C<4,6>TEMP; # SET NIP FL DUMP INDEX                 #
      OMSG(DMSG,0);          # ISSUE *CCP PROTOCOL VIOLATION* MESSAGE  #
      DUMPIND = DUMPIND + 1; # INCREMENT DUMP INDEX                    #
 
      RETURN; 
      END 
      TERM