User Tools

Site Tools


cdc:nos2.source:opl.opl871:deck:rtask

Deck RTASK

4 Modifications

Source

Seq #  *Modification Id* Act 
----------------------------+
00001  M01S00001.rtask   +++|          IDENT  RTASK
Line S00002 Modification History
M01 (Added by) rtask
M02 (Updated by) 253l688
Seq #  *Modification Id* Act 
----------------------------+
00002  M02S00002.253l688 ---|          SST    BEGN
00003  M01S00001.253l688 +++|          SST    BEGN,CMBL
00004  M01S00003.rtask   +++|          LCC    OVERLAY(RTASK,0,0)
00005  M01S00004.rtask   +++|          ENTRY  RTASK
00006  M01S00005.rtask   +++|          SYSCOM B1
00007  M01S00006.rtask   +++| RTASK    TITLE  RTASK - RECOVER TERMINAL TASK.
00008  M01S00007.rtask   +++|*COMMENT  RTASK - RECOVER TERMINAL TASK.
Line S00008 Modification History
M01 (Added by) rtask
M02 (Updated by) 281l803
Seq #  *Modification Id* Act 
----------------------------+
00009  M02S00008.281l803 ---|          COMMENT  COPYRIGHT CONTROL DATA CORPORATION.  1980.
00010  M01S00001.281l803 +++|          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
00011  M01S00009.rtask   +++| RTASK    SPACE  4,10
00012  M01S00010.rtask   +++|***       RTASK - RECOVER TERMINAL TASK.
00013  M01S00011.rtask   +++|*
00014  M01S00012.rtask   +++|*         E. D. REDIG.       80/05/07.
00015  M01S00013.rtask   +++| RTASK    SPACE  4,40
Line S00014 Modification History
M01 (Added by) rtask
M02 (Updated by) 281l803
Seq #  *Modification Id* Act 
----------------------------+
00016  M02S00014.281l803 ---|***       THE TASK *RTASK* IS A CONTROL DATA CORPORATION SUPPLIED
00017  M01S00002.281l803 +++|***       THE TASK *RTASK* IS A CONTROL DATA SYSTEMS SUPPLIED
00018  M01S00015.rtask   +++|*         RECOVERY TASK THAT SHOULD HANDLE MOST TRANSACTION
00019  M01S00016.rtask   +++|*         APPLICATION NEEDS.  HOWEVER, SOME CUSTOMERS MAY WISH
00020  M01S00017.rtask   +++|*         TO MODIFY *RTASK* TO MEET THEIR SPECIAL REQUIREMENTS.
00021  M01S00018.rtask   +++|*
00022  M01S00019.rtask   +++|*         TERMINAL DISCONNECTS, *NAM* ABORTS, *TAF* ABORTS, AND
00023  M01S00020.rtask   +++|*         SYSTEM CRASHES WILL MEAN THAT THE TERMINAL MUST GO
00024  M01S00021.rtask   +++|*         THROUGH THE LOGIN PROCEDURES WITH *TAF*.  UPON TERMINAL
00025  M01S00022.rtask   +++|*         LOGIN *RTASK* WOULD BE CALLED.  *RTASK* THEN DOES THE
00026  M01S00023.rtask   +++|*         FOLLOWING.
00027  M01S00024.rtask   +++|*
00028  M01S00025.rtask   +++|*         1.  IF A RECOVERABLE TRANSACTION IS NO LONGER RERUNNABLE,
00029  M01S00026.rtask   +++|*             *RTASK* TELLS THE TERMINAL OPERATOR THAT RECOVERY HAS
00030  M01S00027.rtask   +++|*             OCCURRED, THAT THE RECOVERABLE TRANSACTION WILL NOT
00031  M01S00028.rtask   +++|*             BE RERUN AUTOMATICALLY, TO ENTER THE NEXT INPUT, AND
00032  M01S00029.rtask   +++|*             CEASES.  THIS SITUATION OCCURS WHEN AN INPUT/OUTPUT
00033  M01S00030.rtask   +++|*             ERROR OCCURRED ON THE *TAF* RECOVERY FILE.
00034  M01S00031.rtask   +++|*
00035  M01S00032.rtask   +++|*         2.  IF THE TRANSACTION UNIT IS NOT RECOVERABLE, *RTASK*
00036  M01S00033.rtask   +++|*             SENDS *READY* TO INDICATE THE TERMINAL OPERATOR
00037  M01S00034.rtask   +++|*             SHOULD ENTER THE NEXT COMMAND, AND CEASES.
00038  M01S00035.rtask   +++|*
00039  M01S00036.rtask   +++|*         3.  IF THE TRANSACTION COMMIT UNIT IS SECURE AND THE DATA
00040  M01S00037.rtask   +++|*             BASE COMMIT UNIT IS COMMITTED, *RTASK* SENDS THE TERM-
00041  M01S00038.rtask   +++|*             INAL CONFIRMATION MESSAGE, AND CEASES.  THE TERMINAL
00042  M01S00039.rtask   +++|*             CONFIRMATION MESSAGE IS STORED ON THE *TAF* RECOVERY
00043  M01S00040.rtask   +++|*             FILE AS A RESULT OF THE SECURE REQUEST.
00044  M01S00041.rtask   +++|*
00045  M01S00042.rtask   +++|*         4.  *RTASK* CALLS *CTASK*.  *CTASK* REQUESTS A NEW TRANS-
00046  M01S00043.rtask   +++|*             ACTION SEQUENCE NUMBER AND RETURNS THE BEGIN-COMMIT
00047  M01S00044.rtask   +++|*             HISTORY TO *TAF CRM*.  *CTASK* THEN MAKES A RERUN
00048  M01S00045.rtask   +++|*             REQUEST.  THE RERUN REQUEST TURNS OFF THE RECOVERY
00049  M01S00046.rtask   +++|*             STATUS AND RETRIEVES TERMINAL INPUT FROM THE *TAF*
00050  M01S00047.rtask   +++|*             RECOVERY FILE.  THE TRANSACTION WILL BE RUN USING THE
00051  M01S00048.rtask   +++|*             NEW SEQUENCE NUMBER.  *ITASK* WILL LATER PROCESS THE
00052  M01S00049.rtask   +++|*             INPUT AS IF THE INPUT HAD COME FROM THE TERMINAL.
00053  M01S00050.rtask   +++|
00054  M01S00051.rtask   +++|
00055  M01S00052.rtask   +++|***       COMMON DECKS.
00056  M01S00053.rtask   +++|
00057  M01S00054.rtask   +++|
00058  M01S00055.rtask   +++|*CALL     COMCMAC
00059  M01S00056.rtask   +++|*CALL     COMKTAF
00060  M01S00057.rtask   +++|*CALL     COMKFLD
00061  M01S00058.rtask   +++|*CALL     COMKIPR
00062  M01S00059.rtask   +++|*CALL     COMKMAC
00063  M01S00060.rtask   +++| BEGN     BSS    0           SAVE ORIGIN COUNTER
00064  M01S00061.rtask   +++|*CALL     COMKCBD
00065  M01S00062.rtask   +++|          LIST   X
00066  M01S00063.rtask   +++|*CALL     COMKTRF
00067  M01S00064.rtask   +++|          LIST   -X
00068  M01S00065.rtask   +++|*CALL     COMKTSC
00069  M01S00066.rtask   +++|          ORG    BEGN        RESTORE ORIGIN COUNTER
00070  M01S00067.rtask   +++| RTASK    SPACE  4,15
00071  M01S00068.rtask   +++|***       COMMUNICATION BLOCK HEADER WORDS AND MESSAGES.
00072  M01S00069.rtask   +++|*
00073  M01S00070.rtask   +++|*T  TMSW    60/    CASE
Figure TMSW

029 CASE3059 CASE

00074  M01S00071.rtask   +++|*T, TMSW+1  60/    RECOVERY FLAG (RF)
Figure TMSW+1

029 RECOVERY FLAG (RF)3059 RECOVERY FLAG (RF)

00075  M01S00072.rtask   +++|*T, TMSW+2  60/    OLDID
Figure TMSW+2

029 OLDID3059 OLDID

00076  M01S00073.rtask   +++|*T, TMSW+3  60/    NEWID
Figure TMSW+3

029 NEWID3059 NEWID

00077  M01S00074.rtask   +++|*T, TMSW+5  60/    *RERUN* STATUS (RS)
Figure TMSW+5

029 *RERUN* STATUS (RS)3059 *RERUN* STATUS (RS)

00078  M01S00075.rtask   +++|*
00079  M01S00076.rtask   +++|*           CASE   = 1, RECOVER INTERACTIVE USER.
00080  M01S00077.rtask   +++|*           RF     BIT 59 = 1, IF *CRM* AUTOMATIC RECOVERY USED.
00081  M01S00078.rtask   +++|*                  BIT 0 = 1, IF *TAF* AUTOMATIC RECOVERY USED.
00082  M01S00079.rtask   +++|*           OLDID  =  PREVIOUS *CRM* IDENTIFIER.
00083  M01S00080.rtask   +++|*           NEWID  =  CURRENT *CRM* IDENTIFIER.
00084  M01S00081.rtask   +++|*           RS     = 0, IF *SRERUN* SUCCESSFUL.
00085  M01S00082.rtask   +++|*                  = 1, IF *SRERUN* NOT SUCCESSFUL.
00086  M01S00083.rtask   +++|*                  = -1, IF DATA BASE FILE DOWN.
00087  M01S00084.rtask   +++|
00088  M01S00085.rtask   +++|
00089  M01S00086.rtask   +++|          BSS    CMBL        RESERVE SPACE FOR COMMUNICATION BLOCK
00090  M01S00087.rtask   +++| RTASK    SPACE  4,20
00091  M01S00088.rtask   +++|**        RTASK - RECOVER TERMINAL TASK.
00092  M01S00089.rtask   +++|*
00093  M01S00090.rtask   +++|*         ENTRY  (TMSW+1) = RECOVERY FLAG.
00094  M01S00091.rtask   +++|*
00095  M01S00092.rtask   +++|*         EXIT   TERMINAL RECOVERY MESSAGE.
00096  M01S00093.rtask   +++|*                (TMSW) = RECOVER INTERACTIVE USER CASE.
00097  M01S00094.rtask   +++|*                (TMSW+1) = RECOVERY FLAG.
00098  M01S00095.rtask   +++|*                (TMSW+2) = OLDID.
00099  M01S00096.rtask   +++|*                (TMSW+3) = NEWID.
00100  M01S00097.rtask   +++|*
00101  M01S00098.rtask   +++|*         ERROR  TO *RTA3* IF ERROR AND NORMAL CEASE.
00102  M01S00099.rtask   +++|*                TO *RTA5* IF ERROR AND ABNORMAL CEASE.
00103  M01S00100.rtask   +++|*
00104  M01S00101.rtask   +++|*         USES   X - 1, 2, 3, 4, 5, 6, 7.
00105  M01S00102.rtask   +++|*                A - 1, 2, 3, 5, 6, 7.
00106  M01S00103.rtask   +++|*                B - 1.
00107  M01S00104.rtask   +++|*
00108  M01S00105.rtask   +++|*         MACROS BLDABH, CALLTRN, CEASE, FMSG, MOVE, SCALL, WAIT,
00109  M01S00106.rtask   +++|*                WAITINP.
00110  M01S00107.rtask   +++|
00111  M01S00108.rtask   +++|
00112  M01S00109.rtask   +++| RTASK    SB1    1
00113  M01S00110.rtask   +++|
00114  M01S00111.rtask   +++|*         ISSUE *TSTAT* REQUEST TO OBTAIN STATUS OF TRANSACTION.
00115  M01S00112.rtask   +++|
00116  M01S00113.rtask   +++|          SCALL  TSTAT,(RTAA,RTAB,RTAC,RTAD,RTAE,RTAF,RTAG,RTAH,RTAI,RTA
00117  M01S00114.rtask   +++|,J,RTAK,RTAL,RTAM)           ISSUE *TSTAT* REQUEST
00118  M01S00115.rtask   +++|          SA2    RTAA        GET STATUS OF REQUEST
00119  M01S00116.rtask   +++|          SX5    RTAAC
00120  M01S00117.rtask   +++|          SX4    X2-TSRU     RECOVERY UNAVAILABLE
00121  M01S00118.rtask   +++|          ZR     X4,RTA2     IF RECOVERY UNAVAILABLE
00122  M01S00119.rtask   +++|          SX5    RTAAA
00123  M01S00120.rtask   +++|          SX4    X2-TSNE     NO ERRORS STATUS
00124  M01S00121.rtask   +++|          NZ     X4,RTA5     IF ERRORS IN *TSTAT*
00125  M01S00122.rtask   +++|          SA2    RTAC        GET TRANSACTION STEP
00126  M01S00123.rtask   +++|          SX5    RTAAC
00127  M01S00124.rtask   +++|          SA3    RTAE        GET TRANSACTION TYPE
00128  M01S00125.rtask   +++|          SX4    X3-TYIT     TERMINAL USER TYPE
00129  M01S00126.rtask   +++|          NZ     X4,RTA14    IF NOT TERMINAL USER
00130  M01S00127.rtask   +++|          ZR     X2,RTA2     IF TERMINAL TRANSACTION NON-RECOVERABLE
00131  M01S00128.rtask   +++|          SX4    X2-CSTA
00132  M01S00129.rtask   +++|          ZR     X4,RTA2     IF TRANSACTION ABORT STEP
00133  M01S00130.rtask   +++|          SX5    RTAAB
00134  M01S00131.rtask   +++|          SX4    X2-CSTN     NO LONGER RERUNNABLE STEP
00135  M01S00132.rtask   +++|          ZR     X4,RTA2     IF STEP NO LONGER RERUNNABLE
00136  M01S00133.rtask   +++|
00137  M01S00134.rtask   +++|*         TRANSACTION WILL BE RERUN OR PUSHED THROUGH TO
00138  M01S00135.rtask   +++|*         COMPLETION BY SENDING THE *SECURE* MESSAGE.
00139  M01S00136.rtask   +++|
00140  M01S00137.rtask   +++|          SX6    TYIT        SET RECOVER INTERACTIVE USER CASE
00141  M01S00138.rtask   +++|          SA2    RTAK        GET *OLDID*
00142  M01S00139.rtask   +++|          SA3    RTAM        GET *NEWID*
00143  M01S00140.rtask   +++|          SA6    TMSW        STORE CASE IN COMMUNICATION BLOCK
00144  M01S00141.rtask   +++|          BX6    X2
00145  M01S00142.rtask   +++|          BX7    X3
00146  M01S00143.rtask   +++|          SA6    TMSW+2      STORE *OLDID* IN COMMUNICATION BLOCK
00147  M01S00144.rtask   +++|          SA7    TMSW+3      STORE *NEWID* IN COMMUNICATION BLOCK
00148  M01S00145.rtask   +++|          SX7    MAXWS*10    MAXIMUM MESSAGE LENGTH
00149  M01S00146.rtask   +++|          SX6    4           SET MESSAGE UNITS TO DISPLAY
00150  M01S00147.rtask   +++|          SA7    RTAP        STORE MAXIMUM MESSAGE LENGTH
00151  M01S00148.rtask   +++|          SA6    RTAQ        STORE MESSAGE UNITS
00152  M01S00149.rtask   +++|
00153  M01S00150.rtask   +++|*         ISSUE *RSECURE* REQUEST TO OBTAIN *SECURE* MESSAGE.
00154  M01S00151.rtask   +++|*         IF NO *SECURE* MESSAGE, RERUN TRANSACTION.
00155  M01S00152.rtask   +++|
00156  M01S00153.rtask   +++|          SCALL  RSECURE,(RTAN,RTAO,RTAP,RTAQ,RTAR,RTAS)
00157  M01S00154.rtask   +++|          SA2    RTAO        GET STATUS OF REQUEST
00158  M01S00155.rtask   +++|          SX4    X2-TSNM     NO MESSAGE STATUS
00159  M01S00156.rtask   +++|          ZR     X4,RTA4     IF NO MESSAGE FROM *RSECURE*
00160  M01S00157.rtask   +++|          SX4    X2-TSNE     NO ERRORS STATUS
00161  M01S00158.rtask   +++|          SX5    RTAAA
00162  M01S00159.rtask   +++|          NZ     X4,RTA5     IF ERRORS IN *RSECURE*
00163  M01S00001.ns2145  +++|          SA2    RTAI
00164  M01S00002.ns2145  +++|          NZ     X2,RTA4     IF *CDCS* USED
00165  M01S00160.rtask   +++|          SA2    RTAG
00166  M01S00161.rtask   +++|          ZR     X2,RTA1     IF *CRM* NOT USED
00167  M01S00162.rtask   +++|
00168  M01S00163.rtask   +++|*         IF *CRM* CURRENT BEGIN-COMMIT ID IS SUCCESSFUL, *SEND*
00169  M01S00164.rtask   +++|*         *SECURE* MESSAGE ELSE CALL *CTASK* TO RERUN THE TRANSACTION.
00170  M01S00165.rtask   +++|
00171  M01S00166.rtask   +++|          SA2    RTAM
00172  M01S00167.rtask   +++|          NZ     X2,RTA4     IF *NEWID* NOT ZERO
00173  M01S00168.rtask   +++|
00174  M01S00169.rtask   +++|*         ISSUE *BLDABH* REQUEST TO BUILD APPLICATION BLOCK HEADER.
00175  M01S00170.rtask   +++|
00176  M01S00171.rtask   +++| RTA1     SCALL  BLDABH,(RTAT,RTAQ,RTAU,RTAR,RTAV,RTAS)
00177  M01S00172.rtask   +++|
00178  M01S00173.rtask   +++|*         ISSUE *SEND* REQUEST TO SEND THE SECURE MESSAGE AND CEASE.
00179  M01S00174.rtask   +++|
00180  M01S00175.rtask   +++|          SCALL  SEND,(RTAN,RTAP,RTAW,RTAX)
00181  M01S00176.rtask   +++|
00182  M01S00177.rtask   +++| RTA2     RJ     SND         SEND MESSAGE
00183  M01S00178.rtask   +++| RTA3     CEASE              EXIT TASK WITH CEASE
00184  M01S00001.rtask2  +++|
00185  M01S00002.rtask2  +++| RTA3.1   CEASE  -1          CEASE BUT TERMINAL WILL REMAIN LOCKED
00186  M01S00179.rtask   +++|
00187  M01S00180.rtask   +++|*         CALL *CTASK* TO RERUN THE TRANSACTION.
00188  M01S00181.rtask   +++|
00189  M01S00182.rtask   +++| RTA4     SX5    RTAAE
00190  M01S00183.rtask   +++|          RJ     SND         SEND MESSAGE
00191  M01S00184.rtask   +++|          CALLRTN  RTAZ      CALL *CTASK*
00192  M01S00185.rtask   +++|          SA2    TMSW+5      GET *RERUN* STATUS
Line S00186 Modification History
M01 (Added by) rtask
M02 (Updated by) rtask2
Seq #  *Modification Id* Act 
----------------------------+
00193  M02S00186.rtask2  ---|          ZR     X2,RTA3     IF TRANSACTION WAS RERUNNABLE
00194  M01S00003.rtask2  +++|          ZR     X2,RTA3.1   IF TRANSACTION WAS RERUNNABLE
00195  M01S00187.rtask   +++|          NG     X2,RTA6     IF DATA BASE FILE DOWN
00196  M01S00188.rtask   +++|          SX5    RTAAF
00197  M01S00189.rtask   +++| RTA5     RJ     SND         SEND MESSAGE
00198  M01S00190.rtask   +++|          CEASE  2           ABNORMAL CEASE WITH DUMP
00199  M01S00191.rtask   +++|
00200  M01S00192.rtask   +++|*         RECOVERY NOT POSSIBLE NOW BECAUSE DATA BASE FILE IS
00201  M01S00193.rtask   +++|*         DOWN.  SEND MENU OF OPTIONS TO TAKE.
00202  M01S00194.rtask   +++|
00203  M01S00195.rtask   +++| RTA6     SX6    B0+         MESSAGE COUNT
00204  M01S00196.rtask   +++|          SA6    RTSA
00205  M01S00197.rtask   +++| RTA7     SA2    RTSA        GET MESSAGE COUNT
00206  M01S00198.rtask   +++|          SA5    TRTA+X2     GET MESSAGE ADDRESS
00207  M01S00199.rtask   +++|          SX6    X2-TRTAL
00208  M01S00200.rtask   +++|          PL     X6,RTA8     IF END OF TABLE
00209  M01S00201.rtask   +++|          SX6    X2+B1       INCREMENT MESSAGE COUNT
00210  M01S00202.rtask   +++|          SA6    A2
00211  M01S00203.rtask   +++|          RJ     SND         SEND MESSAGE
00212  M01S00204.rtask   +++|          EQ     RTA7        GET NEXT MESSAGE
00213  M01S00205.rtask   +++|
00214  M01S00206.rtask   +++|*         SAVE C.B. MESSAGE AREA AND THEN REQUEST OPTION.
00215  M01S00207.rtask   +++|
00216  M01S00208.rtask   +++| RTA8     MOVE   4,TMSW,RTSC SAVE C.B. MESSAGE AREA
00217  M01S00209.rtask   +++| RTA9     SX6    300
00218  M01S00210.rtask   +++|          SA6    RTSG
00219  M01S00211.rtask   +++|          WAITINP  RTSG
00220  M01S00212.rtask   +++|          SA1    TMSW
00221  M01S00213.rtask   +++|          SX3    X1-1
00222  M01S00214.rtask   +++|          ZR     X3,RTA11    IF TERMINAL TIMEOUT
00223  M01S00215.rtask   +++|          RJ     SFN         SPACE FILL NAME
00224  M01S00216.rtask   +++|          SA2    RTSD
00225  M01S00217.rtask   +++|          BX3    X2-X6
00226  M01S00218.rtask   +++|          ZR     X3,RTA10    IF WAIT AND TRY AGAIN
00227  M01S00219.rtask   +++|          SA2    RTSE
00228  M01S00220.rtask   +++|          BX3    X2-X6
00229  M01S00221.rtask   +++|          ZR     X3,RTA12    IF LOG OFF
00230  M01S00222.rtask   +++|          SA2    A2+B1
00231  M01S00223.rtask   +++|          BX3    X2-X6
00232  M01S00224.rtask   +++|          ZR     X3,RTA13    IF ENTER NEXT TRANSACTION
00233  M01S00225.rtask   +++|          SX5    RTAAT
00234  M01S00226.rtask   +++|          RJ     SND         SEND MESSAGE
00235  M01S00227.rtask   +++|          EQ     RTA9        REQUEST OPTION
00236  M01S00228.rtask   +++|
00237  M01S00229.rtask   +++|*         TAF WILL WAIT 5 MINUTES BEFORE ATTEMPTING RERUN
00238  M01S00230.rtask   +++|*         OF TRANSACTION.
00239  M01S00231.rtask   +++|
00240  M01S00232.rtask   +++| RTA10    SX5    RTAAU
00241  M01S00233.rtask   +++|          RJ     SND         SEND MESSAGE
00242  M01S00234.rtask   +++|          WAIT   RTSB        WAIT FOR 5 MINUTES
00243  M01S00235.rtask   +++|          MOVE   4,RTSC,TMSW RESTORE C.B. MESSAGE AREA
00244  M01S00236.rtask   +++|          EQ     RTA4        RERUN TRANSACTION
00245  M01S00237.rtask   +++|
00246  M01S00238.rtask   +++|*         TERMINAL TIMEOUT, OPTION B ASSUMED.
00247  M01S00239.rtask   +++|
00248  M01S00240.rtask   +++| RTA11    SX5    RTAAS
00249  M01S00241.rtask   +++|          RJ     SND         SEND MESSAGE
00250  M01S00242.rtask   +++|
00251  M01S00243.rtask   +++|*         LOG OFF WITH THE PREVIOUS RECOVERABLE INFORMATION
00252  M01S00244.rtask   +++|*         REMAINING INTACT.
00253  M01S00245.rtask   +++|
00254  M01S00246.rtask   +++| RTA12    SX5    RTAAV
00255  M01S00247.rtask   +++|          RJ     SND         SEND MESSAGE
00256  M01S00248.rtask   +++|          LOGT   B1          LOG TERMINAL OUT
00257  M01S00249.rtask   +++|          EQ     RTA3        CEASE
00258  M01S00250.rtask   +++|
00259  M01S00251.rtask   +++|*         ALLOW ENTRY OF NEXT TRANSACTION.  THE PREVIOUS
00260  M01S00252.rtask   +++|*         RECOVERABLE INFORMATION WILL BE LOST.
00261  M01S00253.rtask   +++|
00262  M01S00254.rtask   +++| RTA13    SX5    RTAAW
00263  M01S00255.rtask   +++|          RJ     SND         SEND MESSAGE
00264  M01S00256.rtask   +++|          EQ     RTA3        CEASE
00265  M01S00257.rtask   +++|
00266  M01S00258.rtask   +++|*         LOG INTERACTIVE TERMINAL USER OFF WITH THE PREVIOUS
00267  M01S00259.rtask   +++|*         RECOVERABLE INFORMATION REMAINING INTACT.
00268  M01S00260.rtask   +++|
00269  M01S00261.rtask   +++| RTA14    SX4    X2-CSNR
00270  M01S00262.rtask   +++|          ZR     X4,RTA3     IF NON-RECOVERABLE TRANSACTION
00271  M01S00263.rtask   +++|          SX4    X2-CSCE
00272  M01S00264.rtask   +++|          ZR     X4,RTA3     IF CEASE/JOB END
00273  M01S00265.rtask   +++|          SX5    RTAAX
00274  M01S00266.rtask   +++|          RJ     SND         SEND MESSAGE
00275  M01S00267.rtask   +++|          LOGT   B1          LOG TERMINAL OUT
00276  M01S00268.rtask   +++|          EQ     RTA3        CEASE
00277  M01S00269.rtask   +++|
00278  M01S00270.rtask   +++|*         *TSTAT* REQUEST PARAMETERS.
00279  M01S00271.rtask   +++|
00280  M01S00272.rtask   +++| RTAA     CON    0           STATUS OF *TSTAT* REQUEST
00281  M01S00273.rtask   +++| RTAB     DATA   4HSTEP      KEYWORD *STEP*
00282  M01S00274.rtask   +++| RTAC     CON    0           TRANSACTION STEP
00283  M01S00275.rtask   +++| RTAD     DATA   4HTRAN      KEYWORD *TRAN*
00284  M01S00276.rtask   +++| RTAE     CON    0           TRANSACTION TYPE
00285  M01S00277.rtask   +++| RTAF     DATA   3HCRM       KEYWORD *CRM*
00286  M01S00278.rtask   +++| RTAG     CON    0           *CRM* TRANSACTION USAGE
00287  M01S00279.rtask   +++| RTAH     DATA   4HCDCS      KEYWORD *CDCS*
00288  M01S00280.rtask   +++| RTAI     CON    0           *CDCS* TRANSACTION USAGE
00289  M01S00281.rtask   +++| RTAJ     DATA   5HOLDID     KEYWORD *OLDID*
00290  M01S00282.rtask   +++| RTAK     CON    0           PREVIOUS *CRM* IDENTIFIER
00291  M01S00283.rtask   +++| RTAL     DATA   5HNEWID     KEYWORD *NEWID*
00292  M01S00284.rtask   +++| RTAM     CON    0           CURRENT *CRM* IDENTIFIER
00293  M01S00285.rtask   +++|
00294  M01S00286.rtask   +++|*         *RSECURE* REQUEST PARAMETERS.
00295  M01S00287.rtask   +++|
00296  M01S00288.rtask   +++| RTAN     BSS    MAXWS       MESSAGE BUFFER
00297  M01S00289.rtask   +++| RTAO     CON    0           STATUS OF *RSECURE* REQUEST
00298  M01S00290.rtask   +++| RTAP     CON    0           MESSAGE LENGTH
00299  M01S00291.rtask   +++| RTAQ     CON    0           MESSAGE UNITS
00300  M01S00292.rtask   +++| RTAR     CON    0           FORMAT EFFECTOR
00301  M01S00293.rtask   +++| RTAS     CON    0           TRANSPARENT MODE
00302  M01S00294.rtask   +++|
00303  M01S00295.rtask   +++|*         *BLDABH* REQUEST PARAMETERS.
00304  M01S00296.rtask   +++|
00305  M01S00297.rtask   +++| RTAT     DATA   3LACT       APPLICATION CHARACTER TYPE
00306  M01S00298.rtask   +++| RTAU     DATA   3LNFE       FORMAT EFFECTORS
00307  M01S00299.rtask   +++| RTAV     DATA   3LXPT       TRANSPARENT MODE
00308  M01S00300.rtask   +++|
00309  M01S00301.rtask   +++|*         *SEND* REQUEST PARAMETERS.
00310  M01S00302.rtask   +++|
00311  M01S00303.rtask   +++| RTAW     CON    0           SEND TO ORIGINATING TERMINAL
00312  M01S00304.rtask   +++| RTAX     CON    1           CEASE FLAG
00313  M01S00305.rtask   +++|
00314  M01S00306.rtask   +++| RTAZ     DATA   5LCTASK     CALL TO *CTASK*
00315  M01S00307.rtask   +++|          CON    0
00316  M01S00308.rtask   +++| RTSA     CON    0           MESSAGE COUNT
00317  M01S00309.rtask   +++| RTSB     CON    300         *WAIT* TIME IN SECONDS
00318  M01S00310.rtask   +++| RTSC     BSSZ   4           C.B. STORAGE BUFFER
00319  M01S00311.rtask   +++| RTSD     CON    1HA
00320  M01S00312.rtask   +++| RTSE     CON    1HB
00321  M01S00313.rtask   +++| RTSF     CON    1HC
00322  M01S00314.rtask   +++| RTSG     CON    0           *WAITINP* TIME IN SECONDS
00323  M01S00315.rtask   +++|
00324  M01S00316.rtask   +++|*         SEND MESSAGES.
00325  M01S00317.rtask   +++|
00326  M01S00318.rtask   +++| RTAAA    FMSG   (TASK LOGICAL ERROR.)
00327  M01S00319.rtask   +++| RTAAB    FMSG   (RECOVERY, TRANSACTION NOT RERUNNABLE, ENTER NEXT TRANS
00328  M01S00320.rtask   +++|,ACTION.)
00329  M01S00321.rtask   +++| RTAAC    FMSG   (READY.)
00330  M01S00322.rtask   +++| RTAAE    FMSG   (RECOVERY, RERUNNING TRANSACTION.)
00331  M01S00323.rtask   +++| RTAAF    FMSG   (TAF TRANSACTION NOT RERUNNABLE.)
00332  M01S00324.rtask   +++| RTAAG    FMSG   (RECOVERY NOT POSSIBLE NOW BECAUSE DATA BASE FILE IS DO
00333  M01S00325.rtask   +++|,WN.)
00334  M01S00326.rtask   +++| RTAAH    FMSG   (SELECT DESIRED OPTION FROM FOLLOWING LIST BY ENTERING
00335  M01S00327.rtask   +++|,LETTER.)
00336  M01S00328.rtask   +++| RTAAI    FMSG   ( )
00337  M01S00329.rtask   +++| RTAAJ    FMSG   (A = WAIT 5 MINUTES AND TRY AGAIN.  TAF WILL WAIT 5 MIN
00338  M01S00330.rtask   +++|,UTES)
00339  M01S00331.rtask   +++| RTAAK    FMSG   (    BEFORE ATTEMPTING RERUN OF TRANSACTION.)
00340  M01S00332.rtask   +++| RTAAL    FMSG   ( )
00341  M01S00333.rtask   +++| RTAAM    FMSG   (B = LOG OFF.  THE PREVIOUS RECOVERABLE INFORMATION WIL
00342  M01S00334.rtask   +++|,L)
00343  M01S00335.rtask   +++| RTAAN    FMSG   (    REMAIN INTACT, LOG IN AT A LATER TIME TO ATTEMPT R
00344  M01S00336.rtask   +++|,ERUN.)
00345  M01S00337.rtask   +++| RTAAO    FMSG   ( )
00346  M01S00338.rtask   +++| RTAAP    FMSG   (C = ALLOW ENTRY OF NEXT TRANSACTION.  THE PREVIOUS REC
00347  M01S00339.rtask   +++|,OVERABLE)
00348  M01S00340.rtask   +++| RTAAQ    FMSG   (    INFORMATION WILL BE LOST.)
00349  M01S00341.rtask   +++| RTAAR    FMSG   (?)
00350  M01S00342.rtask   +++| RTAAS    FMSG   (TERMINAL TIMEOUT, OPTION B ASSUMED.)
00351  M01S00343.rtask   +++| RTAAT    FMSG   (VALID OPTIONS ARE A, B OR C.)
00352  M01S00344.rtask   +++| RTAAU    FMSG   (WAITING.)
00353  M01S00345.rtask   +++| RTAAV    FMSG   (TRANSACTION SESSION ENDED.)
00354  M01S00346.rtask   +++| RTAAW    FMSG   (ENTER NEXT TRANSACTION.)
00355  M01S00347.rtask   +++| RTAAX    FMSG   (TERMINAL NOT AVAILABLE.)
00356  M01S00348.rtask   +++|
00357  M01S00349.rtask   +++| TRTA     CON    RTAAG
00358  M01S00350.rtask   +++|          CON    RTAAH
00359  M01S00351.rtask   +++|          CON    RTAAI
00360  M01S00352.rtask   +++|          CON    RTAAJ
00361  M01S00353.rtask   +++|          CON    RTAAK
00362  M01S00354.rtask   +++|          CON    RTAAL
00363  M01S00355.rtask   +++|          CON    RTAAM
00364  M01S00356.rtask   +++|          CON    RTAAN
00365  M01S00357.rtask   +++|          CON    RTAAO
00366  M01S00358.rtask   +++|          CON    RTAAP
00367  M01S00359.rtask   +++|          CON    RTAAQ
00368  M01S00360.rtask   +++|          CON    RTAAR
00369  M01S00361.rtask   +++| TRTAL    EQU    *-TRTA      LENGTH OF MESSAGE TABLE
00370  M01S00362.rtask   +++| SND      SPACE  4,10
00371  M01S00363.rtask   +++|**        SND - SEND MESSAGE.
00372  M01S00364.rtask   +++|*
00373  M01S00365.rtask   +++|*         ENTRY  (X5) = ADDRESS OF MESSAGE.
00374  M01S00366.rtask   +++|*
00375  M01S00367.rtask   +++|*         MACROS SEND.
00376  M01S00368.rtask   +++|
00377  M01S00369.rtask   +++|
00378  M01S00370.rtask   +++| SND      SUBR               ENTRY/EXIT
00379  M01S00371.rtask   +++|          SEND   X5          SEND MESSAGE
00380  M01S00372.rtask   +++|          EQ     SNDX        RETURN
00381  M01S00373.rtask   +++|          SPACE  4,10
00382  M01S00374.rtask   +++|**        COMMON DECKS.
00383  M01S00375.rtask   +++|
00384  M01S00376.rtask   +++|
00385  M01S00377.rtask   +++|*CALL     COMCMVE
00386  M01S00378.rtask   +++|*CALL     COMCSFN
00387  M01S00379.rtask   +++|
00388  M01S00380.rtask   +++|
00389  M01S00381.rtask   +++|          END    RTASK
cdc/nos2.source/opl.opl871/deck/rtask.txt ยท Last modified: by 127.0.0.1