Retro1.org codex

*NOSEQ 
$$$START CDCONL.JSL
CDCONL:  JDL;
/*                                                              */
/*       JOB DESCRIPTOR LIBRARY FOR USE WITH CDC ONLINE SYSTEMS */
/*                                                              */
/*       DEFINE FORMAT LEVELS                                   */
/*                                                              */
VFU1:    VFU      ASSIGN=( 1, 1),
                  ASSIGN=( 2,( 4,28,52)),
                  ASSIGN=( 3,( 7,31,55)),
                  ASSIGN=( 4,(10,34,58)),
                  ASSIGN=( 5,(13,37,61)),
                  ASSIGN=( 6, 1),
                  ASSIGN=( 7,(16,40)),
                  ASSIGN=( 8,(19,43)),
                  ASSIGN=( 9,66),
                  ASSIGN=(10,(22,46)),
                  ASSIGN=(11,(25,49)),
                  ASSIGN=(12,64),
                  TOF=1,BOF=66;
/*                                                              */
VFU2:    VFU      ASSIGN=( 1, 1),
                  ASSIGN=( 6, 1),
                  ASSIGN=( 9,60),
                  ASSIGN=(12,60),
                  TOF=1,BOF=60;
/*                                                              */
/*       DEFINE LANDSCAPE PAGE CHARACTERISTICS                  */
/*                                                              */
PDE1:    PDE      PMODE=LANDSCAPE,
                  BEGIN=( .35, .66),
                  FONTS=L0112C;
/*                                                              */
/*       DEFINE 2UP PORTRAIT PAGE CHARACTERISTICS               */
/*                                                              */
PDE2:    PDE      PMODE=PORTRAIT,
                  BEGIN=( .27, .4),
                  BEGIN=(5.55, .4),
                  FONTS=P1012B;
/*                                                              */
/*       DEFINE PORTRAIT PAGE CHARACTERISTICS FOR DOCUMENTS     */
/*                                                              */
PDE3:    PDE      PMODE=PORTRAIT,
                  BEGIN=( .5, .5),
                  FONTS=P07TCC;
/*                                                              */
/*       DEFINE HOST CHARACTERISTICS                            */
/*                                                              */
/*       MAP CDC ASCII GRAPHICS TO STANDARDS FONTS              */
/*                                                              */
/*       NOTE: GRAVE ACCENT WILL STILL BE IMAGED                */
/*             AS A CENT MARK DUE TO LIMITATION OF              */
/*             STANDARD FONTS.                                  */
/*                                                              */
CDCASC:  CODE     DEFAULT=ASCII,
                  ASSIGN=(X'7B',(X'8B',X'4F',X'9B',X'5F'));
/*                                                              */
/*       DEFINE INPUT PROCESSING CHARACTERISTICS                */
/*                                                              */
         VOLUME   HOST=IBMONL,
                  CODE=CDCASC,
                  OPTIMIZE=(NCC,NDC,NPR);
         LINE     PCCTYPE=IBM3211,
                  VFU=VFU1,
                  UCSB=IGNORE,
                  FCB=IGNORE;
         ACCT     USER=NONE;
/*                                                              */
/*       DEFINE DJDE STRING                                     */
/*                                                              */
/*       NOTE: MUST MATCH THAT DEFINED IN COMDECK *COMSBIO*     */
/*                                                              */
         IDEN     PREFIX=(A'  DJDE '),
                  SKIP=7,
                  OFFSET=0,
                  OPRINFO=NO;
/*                                                              */
/*       TABLE AND CRITERIA DECLARATIONS                        */
/*                                                              */
TX:      TABLE    CONSTANT=(A'UJN          = ');
TZ:      TABLE    CONSTANT=(A'.UCLP, ');
CX:      CRITERIA CONSTANT=(19,15,EQ,TX),LINENUM=(1,15);
CZ:      CRITERIA CONSTANT=(8,7,EQ,TZ);
/*                                                              */
/*       DECLARE BANNER AND TRAILER PROCESSING                  */
/*                                                              */
         BANNER   TEST=(CX OR CZ),
                  HCOUNT=1,
                  TCOUNT=1,
                  HJOBNO=(34,6),
                  TYPE=BANNER;
         RAUX     TEST=CZ;
/*                                                              */
/*       JOB DECLARATIONS                                       */
/*                                                              */
/*       DEFAULT JOB (SAME AS 1X1SMP)                           */
/*                                                              */
DFLT:    JOB;
         OUTPUT   FORMAT=PDE1;
/*                                                              */
/*       1X1SMP: LANDSCAPE SINGLE SIDED                         */
/*                                                              */
1X1SMP:  JOB;
         OUTPUT   FORMAT=PDE1;
/*                                                              */
/*       1X1DUP: LANDSCAPE DOUBLE SIDED                         */
/*                                                              */
1X1DUP:  JOB;
         OUTPUT   DUPLEX=YES,
                  FORMAT=PDE1,
                  SHIFT=(75,75);
/*                                                              */
/*       2UPSMP: PORTRAIT SINGLE SIDED                          */
/*                                                              */
2UPSMP:  JOB;
         OUTPUT   FORMAT=PDE2;
/*                                                              */
/*       2UPDUP: PORTRAIT DOUBLE SIDED                          */
/*                                                              */
2UPDUP:  JOB;
         OUTPUT   DUPLEX=YES,
                  FORMAT=PDE2;
/*                                                              */
/*       1UPSMP: PORTRAIT (DOCUMENT) SINGLE SIDED               */
/*                                                              */
1UPSMP:  JOB;
         LINE     PCCTYPE=IBM3211,
                  VFU=VFU2,
                  UCSB=IGNORE,
                  FCB=IGNORE;
         OUTPUT   FORMAT=PDE3;
/*                                                              */
/*       1UPDUP: PORTRAIT (DOCUMENT) DOUBLE SIDED               */
/*                                                              */
1UPDUP:  JOB;
         LINE     PCCTYPE=IBM3211,
                  VFU=VFU2,
                  UCSB=IGNORE,
                  FCB=IGNORE;
         OUTPUT   DUPLEX=YES,
                  FORMAT=PDE3;
/*                                                              */
         END;
$$$END