Retro1.org codex

          IDENT  CALLTRN 
          ENTRY  CALLTRN
          SYSCOM B1
          TITLE  CALLTRN - CALL TRANSACTION.
*COMMENT  CALLTRN - CALL TRANSACTION.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
 CALLTRN  SPACE  4,10
****      CALLTRN - CALL TRANSACTION.
*
*         A. E. SCHIPPERS    80/05/20.
*
*         CALLTRN IS AN INTERFACE ROUTINE WHICH WILL REQUEST
*         THE INITIATION OF A TRANSACTION UNIT.
 CALLTRN  SPACE  4,20
***       CALLTRN - CALL TRANSACTION.
*
*         ENTRY  (A1) = FWA OF PARAMETER LIST.
*                (X1) = 42/0,18/ADDRESS OF FIRST PARAMETER.
*
*         EXIT   TRANSACTION IS INITIATED.
*
*         USES   A - 2, 6.
*                X - 0, 1, 2, 6.
*                B - 1.
*
*         CALLS  ZFN.
*
*         MACROS ARGERR, CALLTRN.
*
*         NOTE   *ITASK* IS THE ONLY TASK ALLOWED TO SCHEDULE
*                TRANSACTIONS.
 CALLTRN  SPACE  4,10
*         COMMON DECKS CALLED.
 
*CALL     COMKMAC
 
 
          VFD    42/0LCALLTRN,18/CALLTRN
 
 CALLTRN  SUBR               ENTRY/EXIT
          SB1    1
          ZR     X1,CTR1     IF NULL LIST ABORT
          SA2    X1          GET TASK NAME
          BX1    X2
          RJ     ZFN         ZERO FILE NAME
          BX6    X1          STORE TRANSACTION NAME
          SA6    CTRA
          SA2    A2+B1       CHECK IF MORE PARAMETERS
          NZ     X2,CTR1     IF NOT END OF PARAMETER LIST
          CALLTRN  CTRA      ENTER REQUEST
          EQ     CALLTRNX    EXIT
 
 
*         PROCESS ARGUMENT ERROR BY ABORTING PROGRAM.
 
 CTR1     SA1    CALLTRN     GET CALLING ADDRESS
          MX0    -30
          LX1    29-59
          SA2    X1-1
          BX6    -X0*X2
          SA6    CTRA
          ARGERR A6          PROCESS ARGUMENT ERROR
 
 CTRA     BSSZ   2
 
*CALL COMKZFN
          END