Retro1.org codex

          IDENT  CMDUMP
 
          ENTRY  CMDUMP
          ENTRY  KPOINT
 
          TITLE  CMDUMP - DUMP CENTRAL MEMORY / DATA BUFFERS.
*COMMENT  CMDUMP - DUMP CENTRAL MEMORY.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
 CMDUMP   SPACE  4,10
*****     CMDUMP - DUMP CENTRAL MEMORY / DATA BUFFERS.
*         A. J. KOMOR        72/07/24.
*         J. R. HOGUE        72/10/05.
*         B. C. ANTIN        78/03/08.
          SPACE  4
*CALL     COMKMAC
*CALL     COMSPRD
 CMDUMP   SPACE  4,90
***       CMDUMP - PRODUCT SET INTERFACE TO DUMP A TASKS CENTRAL
*                MEMORY, EXCHANGE PACKAGE, AND/OR DATA MANAGER
*                BUFFERS.
*
*         *CMDUMP* WILL FORMAT A REQUEST TO THE TRANSACTION FACILITY
*         TO DUMP THE DESIRED TASK RELATED FIELD LENGTH, EXCHANGE
*         PACKAGE, AND/OR DATA MANAGER BUFFERS.  IF A GIVEN
*         PARAMETER IS NEGATIVE, THE DEFAULT VALUE WILL BE
*         OBTAINED FROM THE PREVIOUS *DSDUMP* REQUEST
*         (IF ONE WAS GIVEN) OTHERWISE THE DEFAULT
*         VALUE WILL BE OBTAINED FROM THE GENERAL TRANSACTION
*         FACILITY DEFAULT VALUES ESTABLISHED AT INITIALIZATION OR
*         CHANGED BY K-DISPLAY COMMANDS.
*
*         CALL FORMAT -
*
*         COBOL -
*
*         ENTER CMDUMP USING FWA,LWA,EP,DB,OQ,QD,FILE1, ... FILEN.
*
*
*         FORTRAN EXTENDED -
*
*         CALL CMDUMP(FWA,LWA,EP,DB,OQ,QD,FILE1,...FILEN)
*
*
*         PARAMETER DEFINITIONS -
*
*         FOR ALL PARAMETERS EXCEPT *QD* USE COMP-1 FOR COBOL AND
*         INTEGER FOR FORTRAN.
*
*         FWA    BEGINNING ADDRESS, LEGAL VALUES:
*                FWA .LT. FL
*                IF NEGATIVE (BIT 17 SET) USE DEFAULT
*
*         LWA    LAST WORD ADDRESS, LEGAL VALUES:
*                FWA .LT. LWA
*                =0, IMPLIES NO DUMP OF FIELD LENGTH
*                IF NEGATIVE (BIT 17 SET) USE DEFAULT
*
*         EP     EXCHANGE PACKAGE, LEGAL VALUES:
*                =0, OPTION NOT DESIRED
*                "0, SELECT OPTION
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT
*
*         DB     DATA BUFFERS DUMP, LEGAL VALUES:
*                =0, OPTION NOT DESIRED
*                "0, SELECT OPTION
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT
*
*         OQ     OUTPUT QUEUE, LEGAL VALUES:
*                =0, DUMP TO BATCH PRINTER
*                =1, DUMP TO E/I 200
*                =2, DUMP TO USER PERMANENT FILE
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT
*
*         QD     QUEUE DESTINATION, LEGAL VALUES:
*                IF PRINTER IS SPECIFIED IN PREVIOUS PARAMETER,
*                PRINTER I.D. IS SPECIFIED IN NUMERIC CHARACTERS
*                RIGHT JUSTIFIED BINARY ZERO FILLED WITHIN A WORD.
*                IF NEGATIVE (BIT 17 SET) USE DEFAULT.
*
*                IF E/I 200 IS SPECIFIED IN PREVIOUS PARAMETER, THE
*                ACCOUNT NUMBER IS SPECIFIED IN DISPLAY CODED LEFT
*                JUSTIFIED CHARACTERS, BINARY ZERO FILLED.
*                MAXIMUM LENGTH IS SEVEN CHARACTERS.
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT.
*
*                IF USER PERMANENT FILE IS SPECIFIED, THE PERMANENT
*                FILE NAME IS SPECIFIED IN DISPLAY CODED LEFT
*                JUSTIFIED CHARACTERS, BINARY ZERO FILLED.
*                ANY LEGAL FILE NAME IS PERMISSIBLE
*                WITH A MAXIMUM OF SEVEN CHARACTERS.
*                IF NEGATIVE (BIT 59 SET) USE DEFAULT.
*
*         FILEN  FILE NAMES OF DATA MANAGER BUFFERS TO BE DUMPED, LEGAL
*                VALUES:
*                4 DISPLAY CHARACTERS LEFT JUSTIFIED.
*                IF NONE ARE GIVEN, ALL FILE BUFFERS WILL BE DUMPED.
*                A MAXIMUM OF 10 FILES IS ALLOWED. IF MORE ARE
*                SPECIFIED THEY ARE IGNORED.
 
 
          VFD    42/0LCMDUMP,18/CMDUMP
 CMDUMP   SUBR               ENTRY/EXIT
          SB1    1
          SA4    X1          PICK UP FWA
          MX5    60-18
          SA3    A1+B1       SECOND PARAMETER POINTER
          BX6    -X5*X4
          SA2    X3+         PICK UP LWA
          BX2    -X5*X2
          SA1    A3+1        THIRD PARAMETER POINTER
          LX2    30
          BX4    X2+X6       LWA+FWA
          SA2    X1          READ EXCHANGE PACKAGE INDICATOR
          SA3    A1+B1       FOURTH PARAMETER
          SX6    X2
          SA1    X3          DATA BASE BUFFER DUMP
          MX7    0
          ZR     X6,CMD1     IF EXCHANGE PACKAGE DUMP NOT DESIRED
          MX7    1
          PL     X2,CMD1     IF NOT DEFAULT
          LX7    -2
 CMD1     SX2    0
          SA3    A3+B1       FIFTH PARAMETER POINTER - OUTPUT QUEUE
          BX6    X4+X7       LWA+FWA+EP
          SX4    X1
          ZR     X4,CMD2     IF DATA BASE BUFFERS NOT DESIRED
          SX2    B1
          LX2    58
          PL     X1,CMD2     IF NOT DEFAULT
          LX2    -2
 CMD2     BX6    X6+X2       LWA+FWA+EP+DB
          SA6    CMDA        SET UP CALL WORD 1
          SA2    X3          OUTPUT QUEUE
          SA4    A3+B1       SIXTH PARAMETER POINTER-QUEUE DESTINATION
          SB3    X2
          BX2    -X5*X2
          SA3    X4          QUEUE DESTINATION
          NZ     B3,CMD3     IF NOT LOCAL PRINTER QUEUE
          MX5    18
          LX3    -18
 CMD3     BX7    X5*X3       EXTRACT QUEUE DESTINATION
          SB2    B1
          BX7    X7+X2       DESTINATION + QUEUE
          MX5    24
          SB3    MAXFN       MAXIMUM NUMBER OF FILE NAMES
          SA7    A6+1
 CMD4     SA4    A4+B1       SEVENTH PARAMETER THRU END - FILE NAMES
          ZR     X4,CMD5     IF END OF LIST
          SA3    X4          PICK UP DB,FN1,...
          BX6    X5*X3       MASK OFF FILE NAMES
          SA6    CMDB+B2
          SB2    B2+B1
          NE     B2,B3,CMD4  IF NOT END OF FILE NAME LIST
 CMD5     SA2    CMDUMP      PICK UP ADDRESS OF CALLER
          MX5    18
          LX5    -12
          SX3    B2-1        COUNT OF THE NUMBER OF FILE NAMES
          BX7    X5*X2
          IX7    X3+X7
          SA7    CMDB        SAVE COUNT
          CMDUMP CMDA        ISSUE REQUEST
          EQ     CMDUMPX     RETURN
 
 MAXFN    EQU    10          MAXIMUM NUMBER OF FILE NAMES
 CMDA     VFD    1/1,1/1,1/0,1/0,8/0,18/3LLWA,12/0,18/3LFWA
          VFD    42/4LQDES,18/2LOQ
 CMDB     VFD    12/0,18/3LADR,26/0,4/1RC  CALL ORIGIN AND FILE COUNT
          BSSZ   MAXFN
 KPOINT   SPACE  4,25
***       KPOINT - PRODUCT SET INTERFACE TO ISSUE THE DESIGNATED
*         TRANSACTION FACILITY K-DISPLAY COMMANDS.
*
*         CALL FORMAT -
*
*         COBOL -
*
*         ENTER  KPOINT  USING  BUF
*
*         FORTRAN EXTENDED -
*
*         CALL KPOINT(BUF)
*
*         PARAMETER DEFINITION -
*
*         BUF - THE ADDRESS OF A CHARACTER STRING CONTAINING THE
*               COMMAND TO BE ISSUED.  THE CHARACTER STRING IS
*               TERMINATED WITH A *.* OR *)* EXCEPT FOR THE
*               *MESSAGE* COMMAND WHERE THE MESSAGE TO BE SENT
*               FOLLOWS THE *.* OR *)* AND TERMINATES ON 6
*               BITS OF BINARY ZEROS.  THE STRING IS LIMITED
*               TO 8 CM WORDS.
 
 
          VFD    42/0LKPOINT,18/KPOINT
 KPOINT   SUBR               ENTRY/EXIT
          SX1    X1
          KPOINT X1          ISSUE REQUEST
          EQ     KPOINTX     RETURN
 
          END