Retro1.org codex

          IDENT  PFHELPR,FWA 
          ABS
          TITLE  PFHELPR - *MAGNET* HELPER FOR TAPE ALTERNATE STORAGE.
          SST
          SYSCOM B1
          ENTRY  PFHELPR
          ENTRY  RFL=
          ENTRY  SSJ=
          SPACE  4,10
*COMMENT  PFHELPR - HELPER FOR TAPE ALTERNATE STORAGE.
          COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
          SPACE  4,10
***       PFHELPR - *MAGNET* HELPER FOR TAPE ALTERNATE STORAGE.
*
*         W. C. WELLS.       86/01/27.
*         P. C. SMITH.       87/03/27.
          SPACE  4,10
***       *PFHELPR* IS CALLED BY *MAGNET* AS PART OF TAPE ALTERNATE
*         STORAGE PROCESSING.  IT COPIES STAGE REQUESTS FROM THE
*         STAGE REQUEST TABLE (WITHIN *MAGNET*) TO THE STAGE REQUEST
*         FILE.  THIS FILE IS THEN READ BY *PFRES*.
          SPACE  4,10
*         SYMBOLIC COMMON DECKS.
 
 
*CALL     COMCMAC
*CALL     COMCCMD
*CALL     COMSMTX
*CALL     COMSSSD
*CALL     COMSPFM
          SPACE  4,10
*         STORAGE ALLOCATION.
 
 
          ORG    110B
 FWA      BSS    0
 
 FBUFL    EQU    2001B
 SSJ=     EQU    0
 
 F        BSS    0           STAGE REQUEST FILE
 STRQ     FILEB  FBUF,FBUFL
 
 RPVB     RPVBLK END         REPRIEVE BLOCK
          TITLE  MAIN PROGRAM.
 PFHELPR  BSS    0           ENTRY
          SB1    1
          RJ     PRS
          EQ     PFH2        SKIP ROLLOUT
 
*         CHECK FOR STAGE REQUESTS.
 
 PFH1     ROLLOUT  PFHC
 PFH2     RJ     GSR         CHECK FOR STAGE REQUESTS
          NG     B6,END      IF CANNOT READ REQUESTS
          NE     B6,B1,PFH1  IF NOT ENOUGH REQUESTS TO ATTACH FILE
 
*         ATTACH FILE TO CLEAN UP *MAGNET*-S REQUEST TABLE.
 
          ATTACH F
          SA1    X2
          MX0    -8
          AX1    10
          BX1    -X0*X1
          NZ     X1,PFH1     IF ERROR IN ATTACH
          SKIPEI F,R
          WRITE  X2,*
          SB2    PFHB        INFORM MAGNET THAT FILE IS ATTACHED
          RJ     SRM
 
*         GET STAGE REQUEST.
 
 PFH3     RJ     GSR         GET NEXT STAGE REQUEST
          NG     B6,PFH4     IF CANNOT READ REQUESTS
          ZR     B6,PFH4     IF NO REQUESTS
          WRITEW F,B6,PFTBL
          EQ     PFH3        GET NEXT REQUEST
 
*         IF NO MORE REQUESTS, RELEASE FILE AND CLEAR BIT.
 
 PFH4     WRITER F,R
          UNLOAD F
 PFH5     SB2    PFHA        INFORM *MAGNET* THAT FILE IS RELEASED
          RJ     SRM
          ZR     X1,PFH1     IF SUCCESSFUL
          RECALL             GIVE UP CPU
          EQ     PFH5        TRY AGAIN
 
 
 PFHA     VFD    12/AIB,24/,6/0,18/1   CLEAR *FILE ATTACHED* BIT
 PFHB     VFD    12/AIB,24/,6/1,18/1   SET *FILE ATTACHED* BIT
 PFHC     VFD    60/60
 END      SPACE  4,10
**        END - END PROGRAM.
*
 
 
 END      MESSAGE  (=C*PFHELPR ABORTED.*)
          ENDRUN
          SPACE  4,10
*         COMMON DECKS.
 
 
*CALL     COMCCIO
*CALL     COMCCPM
*CALL     COMCPFM
*CALL     COMCSYS
          LIST   X
*CALL     COMCSRI
          LIST   *
*CALL     COMCWTW
          TITLE  PRESET.
          USE    BUFFERS
 PRS      SPACE  4,10
**        PRS - PRESET.
*
 
 
 FBUF     BSS    0           OUTPUT BUFFER
 PRS      SUBR               ENTRY/EXIT
          REPRIEVE  RPVB,SET,237B  SET REPRIEVE PROCESSING
          MACHID PRSA        GET MACHINE ID
          SA1    PRSA
          SA2    F           SET ID INTO STAGE REQUEST FILE NAME
          LX1    24
          BX6    X1+X2
          SA6    A2
          GETJN  PRSB        GET JOB NAME
          SA1    PRSB
          SA2    PFHA        SET JOB NAME IN *MAGNET* REQUESTS
          SA3    PFHB
          LX1    24-36
          BX7    X1+X2
          BX6    X1+X3
          SA7    A2
          SA6    A3
          SB2    PFHA        SEND *CLEAR BIT* REQUEST TO MAGNET
          RJ     SRM
          EQ     PRSX        RETURN
 
 
 PRSA     BSS    1           MACHINE ID BUFFER
 PRSB     BSS    1           JOB NAME BUFFER
 
          BSS    FBUF+FBUFL+1-*   ALLOCATE ENOUGH SPACE FOR BUFFER
          BSS    8           PREVENT LOOKAHEAD REFERENCE BEYOND FL
 RFL=     END