Retro1.org codex

User Tools

Site Tools

Trace: • RCTASK
cdc:nos2.source:opl871:rctask

Table of Contents

RCTASK

Table Of Contents

  • [00006] RCTASK - RECOVER *CDCS* TRANSACTIONS.
  • [00010] RECOVER *CDCS* TRANSACTIONS.
  • [00076] RECOVER *CDCS* TRANSACTIONS.

Source Code

RCTASK.txt 
  1.           IDENT  RCTASK
  2.           LCC    OVERLAY(RCTASK,0,0)
  3.           SST    BEGN,CMBL
  4.           ENTRY  RCTASK
  5.           SYSCOM B1
  6.           TITLE  RCTASK - RECOVER *CDCS* TRANSACTIONS.
  7. *COMMENT  RCTASK - RECOVER *CDCS* TRANSACTIONS.
  8.           COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
  9.  RCTASK   SPACE  4,10
  10. ***       RCTASK - RECOVER *CDCS* TRANSACTIONS.
  11. *
  12. *         E. D. REDIG.       81/06/19.
  13.  RCTASK   SPACE  4,20
  14. ***       *RCTASK* RECOVERS RERUNNABLE CDCS TRANSACTIONS
  15. *         AND MUST BE INSTALLED ON THE SYSTEM LIBRARY.
  16. *
  17. *         *RCTASK* READS THE ENTIRE *CRF* BY ISSUING *TSTAT*
  18. *         REQUESTS TO OBTAIN INFORMATION ABOUT EACH USER AND
  19. *         PROCESSES THIS INFORMATION AS FOLLOWS.
  20. *
  21. *         1.  IF *CDCS* MAY NOT BE USED BY THIS TRANSACTION,
  22. *             THEN READ THE NEXT *CRF* ENTRY.
  23. *
  24. *         2.  IF THE TRANSACTION STEP IS NOT *CDCS* DOWN, THEN
  25. *             READ THE NEXT *CRF* ENTRY.
  26. *
  27. *         3.  IF THE TRANSACTION TYPE IS *BTRAN*, THEN GO TO
  28. *             STEP 5.
  29. *
  30. *         4.  IF THE TERMINAL USER IS NOT ACTIVE, THEN READ THE
  31. *             NEXT *CRF* ENTRY.
  32. *
  33. *         5.  ISSUE *SRERUN* TO RERUN THE CDCS TRANSACTION AND
  34. *             READ THE NEXT *CRF* ENTRY.
  35.  RCTASK   SPACE  4,15
  36. ***       DAYFILE MESSAGES ISSUED.
  37. *
  38. *         ABNORMAL COMPLETION.
  39. *
  40. *         * RCTASK - TAF AUTOMATIC RECOVERY NOT INSTALLED.*
  41. *                THE KEYWORD SPECIFIED IN A *TSTAT* REQUEST
  42. *                REQUIRES TAF AUTOMATIC RECOVERY.
  43. *
  44. *         * RCTASK - TASK LOGICAL ERROR.*
  45. *                A LOGICAL ERROR OCCURRED THAT WAS NOT EXPECTED.
  46. *
  47. *         * RCTASK - USER NOT DEFINED IN NETWORK FILE.*
  48. *                THE USER IS NOT DEFINED IN THE NETWORK FILE ON
  49. *                AN *SRERUN* OR *TSTAT* REQUEST.
  50.  RCTASK   SPACE  4,10
  51. ***       COMMON DECKS.
  52.  
  53.  
  54. *CALL     COMCMAC
  55. *CALL     COMKTAF
  56. *CALL     COMKFLD
  57. *CALL     COMKIPR
  58. *CALL     COMKMAC
  59.  
  60. *         SAVE ORIGIN COUNTER TO REMOVE COMMON DECK STORAGE IN
  61. *         *COMKCBD* AND *COMKTSC*.
  62.  
  63.  BEGN     BSS    0           SAVE ORIGIN COUNTER
  64. *CALL     COMKCBD
  65.           LIST   X
  66. *CALL     COMKTRF
  67.           LIST   -X
  68. *CALL     COMKTSC
  69.           ORG    BEGN        RESTORE ORIGIN COUNTER
  70.  RCTASK   SPACE  4,10
  71. ***       COMMUNICATION BLOCK.
  72.  
  73.  
  74.           BSS    CMBL
  75.  RCTASK   SPACE  4,15
  76. ***       RCTASK - RECOVER *CDCS* TRANSACTIONS.
  77. *
  78. *         ENTRY  BOI OF *CRF*.
  79. *
  80. *         EXIT   RERUNNABLE *CDCS* TRANSACTIONS RECOVERED.
  81. *
  82. *         ERROR  TO *RCT4*, IF ERROR ENCOUNTERED.
  83. *
  84. *         USES   X - 1, 2, 3, 4, 6, 7.
  85. *                A - 1, 2, 3, 4, 6, 7.
  86. *                B - 1.
  87. *
  88. *         MACROS CEASE, SCALL, SEND.
  89.  
  90.  
  91.  RCTASK   SB1    1           ENTRY
  92.           SA2    TNAM
  93.           SA3    RCTBL       DAYFILE MESSAGE
  94.           SA1    RCTT
  95.           LX2    59-CBSYS
  96.           BX6    X1
  97.           PL     X2,RCT4     IF NOT SYSTEM ORIGIN TRANSACTION
  98.           SA6    RCTO        INITIALIZE *NEXT* FOR *TSTAT*
  99.  
  100. *         ISSUE *TSTAT* REQUEST TO OBTAIN STATUS OF TRANSACTION.
  101.  
  102.  RCT1     SCALL  TSTAT,(RCTM,RCTN,RCTO,RCTP,RCTQ,RCTR,RCTS,RCTU,RCTV)
  103.           SA1    RCTM
  104.           SA3    RCTAL       DAYFILE MESSAGE
  105.           SX2    X1-TSRU
  106.           ZR     X2,RCT4     IF RECOVERY UNAVAILABLE
  107.           SX2    X1-TSEN
  108.           ZR     X2,RCT5     IF END OF *NEXT* PROCESSING
  109.           SA3    RCTCL       DAYFILE MESSAGE
  110.           SX2    X1-TSUU
  111.           ZR     X2,RCT4     IF USER UNKNOWN
  112.           SA3    RCTBL       DAYFILE MESSAGE
  113.           SX2    X1-TSNE
  114.           NZ     X2,RCT4     IF ERRORS IN *TSTAT*
  115.           SA1    RCTS        GET *CDCS* USAGE
  116.           ZR     X1,RCT1     IF *CDCS* NOT USED BY TRANSACTION
  117.           SA1    RCTQ        GET TRANSACTION STEP
  118.           SX2    X1-CSCD
  119.           NZ     X2,RCT1     IF *CDCS* NOT DOWN
  120.  
  121. *         SET UP *SEND* REQUEST PARAMETERS.
  122.  
  123.           SA1    RCTI
  124.           SA2    RCTJ
  125.           BX6    X1
  126.           BX7    X2
  127.           SA6    RCTH
  128.           SA1    RCTO
  129.           MX3    TRUNN
  130.           BX6    X3*X1
  131.           SA6    A6+B1       USER NAME
  132.           BX2    X6
  133.           SA7    A6+B1
  134.           BX6    X6-X6
  135.           SA6    A7+B1       STATUS OF USER NAME
  136.           BX7    X2
  137.           SA7    RCTL
  138.           SA1    RCTV        GET TRANSACTION TYPE
  139.           SX2    X1-TYBT
  140.           ZR     X2,RCT2     IF *BTRAN* TRANSACTION
  141.  
  142. *         SEND MESSAGE TO TERMINAL TO CHECK IF ACTIVE.
  143.  
  144.           SEND   RCTH
  145.           SA1    RCTH+3      GET STATUS OF USER NAME
  146.           SX2    RCTD        CONNECTION ENDED MESSAGE
  147.           LX1    18
  148.           SX1    X1+         SUPERVISORY MESSAGE FROM NAM
  149.           IX1    X1-X2
  150.           ZR     X1,RCT1     IF TERMINAL NOT ACTIVE
  151.  
  152. *         ISSUE *SRERUN* REQUEST TO RERUN TRANSACTION USING USER NAME.
  153.  
  154.  RCT2     SCALL  SRERUN,(RCTK,RCTL)
  155.           SA1    RCTK        GET STATUS OF REQUEST
  156.           SX2    X1-TSNO
  157.           ZR     X2,RCT1     IF TRANSACTION NOT RERUNNABLE
  158.           SA3    RCTCL
  159.           SX2    X1-TSUU
  160.           ZR     X2,RCT4     IF USER UNKNOWN
  161.           SA3    RCTBL
  162.           SX2    X1-TSNE
  163.           ZR     X2,RCT1     IF NO ERRORS IN *SRERUN*
  164.  
  165. *         IF AN ERROR OCCURS ON *SRERUN* THEN SEND ERROR MESSAGE
  166. *         TO ORIGINATING TERMINAL OR TAF-S DAYFILE AND CONTINUE
  167. *         PROCESSING.
  168.  
  169.           SA1    RCTV        GET TRANSACTION TYPE
  170.           SX2    X1-TYBT
  171.           ZR     X2,RCT3     IF *BTRAN* TRANSACTION
  172.           MX2    -48
  173.           BX6    -X2*X3      MESSAGE ADDRESS AND NUMBER OF WORDS
  174.           SA1    RCTJ
  175.           MX4    1           TERMINAL FLAG
  176.           BX6    X6+X4
  177.           SA6    RCTH        WORD ONE OF *SEND* PARAMETERS
  178.           MX2    48
  179.           LX3    12
  180.           SA4    RCTL
  181.           BX6    X2*X1       APPLICATION BLOCK AND CHARACTER TYPE
  182.           BX3    -X2*X3      TEXT LENGTH COUNT
  183.           BX7    X4          USER NAME
  184.           SA7    A6+B1       WORD TWO OF *SEND* PARAMETERS
  185.           BX6    X6+X3
  186.           BX7    X7-X7
  187.           SA6    A7+B1       WORD THREE OF *SEND* PARAMETERS
  188.           SA7    A6+B1       WORD FOUR OF *SEND* PARAMETERS
  189.           SEND   RCTH        SEND MESSAGE TO ORIGINATING TERMINAL
  190.           EQ     RCT1        READ NEXT ENTRY FROM *CRF*
  191.  
  192.  RCT3     AX3    30
  193.           SX4    X3          MESSAGE ADDRESS
  194.           AX3    18          MESSAGE LENGTH
  195.           BX6    X3
  196.           SA6    RCTW
  197.           SCALL  TMSG,(X4,RCTW)  SEND MESSAGE TO DAYFILE
  198.           EQ     RCT1        READ NEXT ENTRY FROM *CRF*
  199.  
  200. *         A SYSTEM ERROR OCCURRED AND AN ERROR MESSAGE WILL BE PUT
  201. *         IN TAF-S DAYFILE, THEN *RCTASK* WILL CEASE WITH A DUMP.
  202.  
  203.  RCT4     AX3    30
  204.           SX4    X3          MESSAGE ADDRESS
  205.           AX3    18          MESSAGE LENGTH
  206.           BX6    X3
  207.           SA6    RCTW
  208.           SCALL  TMSG,(X4,RCTW)  SEND MESSAGE TO DAYFILE
  209.           CEASE  2           ABNORMAL CEASE WITH DUMP
  210.  
  211.  RCT5     CEASE              EXIT TASK WITH CEASE
  212.  
  213. *         DAYFILE MESSAGES.
  214.  
  215.  RCTA     DATA   C* RCTASK - TAF AUTOMATIC RECOVERY NOT INSTALLED.*
  216.  RCTAL    VFD    12/**10-RCTA*10,18/RCTA,30/*-RCTA
  217.  RCTB     DATA   C* RCTASK - TASK LOGICAL ERROR.*
  218.  RCTBL    VFD    12/**10-RCTB*10,18/RCTB,30/*-RCTB
  219.  RCTC     DATA   C* RCTASK - USER NOT DEFINED IN NETWORK FILE.*
  220.  RCTCL    VFD    12/**10-RCTC*10,18/RCTC,30/*-RCTC
  221.  RCTD     EQU    306030B     CONNECTION ENDED SUPERVISORY MESSAGE
  222.  RCTE     DATA   C* BEGIN TRANSACTION RERUN.*
  223.  RCTF     EQU    *-RCTE
  224.  RCTG     EQU    RCTF*10
  225.  
  226. *         *SEND* REQUEST PARAMETERS.
  227.  
  228.  RCTH     BSSZ   4
  229.  RCTI     VFD    1/1,3/0,1/1,7/0,18/RCTE,12/0,18/RCTF
  230.  RCTJ     VFD    6/2,30/0,4/4,8/0,12/RCTG
  231.  
  232. *         *SRERUN* REQUEST PARAMETERS.
  233.  
  234.  RCTK     CON    0           STATUS OF REQUEST
  235.  RCTL     CON    0           USER NAME
  236.  
  237. *         *TSTAT* REQUEST PARAMETERS.
  238.  
  239.  RCTM     CON    0           STATUS OF *TSTAT* REQUEST
  240.  RCTN     DATA   4HNEXT
  241.  RCTO     CON    0           NEXT USER FROM *CRF*
  242.  RCTP     DATA   4HSTEP
  243.  RCTQ     CON    0           TRANSACTION STEP
  244.  RCTR     DATA   4HCDCS
  245.  RCTS     CON    0           *CDCS* USAGE
  246.  RCTT     DATA   1H          BLANK WORD
  247.  RCTU     DATA   4HTRAN
  248.  RCTV     CON    0           TRANSACTION TYPE
  249.  RCTW     CON    0           MESSAGE LENGTH
  250.  
  251.           END    RCTASK
cdc/nos2.source/opl871/rctask.txt · Last modified: 2023/08/05 17:24 by Site Administrator