Retro1.org codex

User Tools

Site Tools

Trace: • SETCORE
cdc:nos2.source:opl871:setcore

Table of Contents

SETCORE

Table Of Contents

  • [00007] SETCORE - PRESET MEMORY.
  • [00009] PRESET MEMORY.

Source Code

SETCORE.txt 
  1.           IDENT  SETCORE,SETCORE,SETCORE 
  2.           ABS
  3.           SYSCOM B1          DEFINE (B1) = 1
  4.  QUAL$    EQU    1           DEFINE UNQUALIFIED COMMON DECKS
  5. *COMMENT  SETCORE - PRESET MEMORY.
  6.           COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992.
  7.           TITLE  SETCORE - PRESET MEMORY.
  8.  SETCORE  SPACE  4
  9. ***       SETCORE - PRESET MEMORY.
  10. *         R. A. LARSEN.  75/01/03.
  11. *         ADAPTED FROM LINK BY G. R. MANSFIELD.
  12.  SETCORE  SPACE  4
  13. ***              SETCORE PROCESSES THE PRESETTING OF MEMORY TO A
  14. *         SPECIFIED VALUE.
  15.  SETCORE  SPACE  4
  16. ***       SETCORE(P)
  17. *         SETCORE(+P)
  18. *         SETCORE(-P)
  19. *         PRESET MEMORY ACCORDING TO *P*.
  20. *
  21. *         P      VALUE
  22. *         0      ZEROES
  23. *         ZERO   ZEROES
  24. *         INDEF  INDEFINITES
  25. *         INF    INFINITES
  26. *
  27. *         ASSUMED ARGUMENT.
  28. *         P      ZERO
  29.  
  30.  
  31.           ORG    110B
  32.  
  33.  SETCORE  SB1    1           PRESET PROGRAM
  34.           SA1    ACTR        CHECK ARGUMENT COUNT
  35.           BX6    X6-X6       CLEAR VALUE
  36.           SX5    B0          CLEAR SIGN
  37.           BX0    X0-X0       SET DEFAULT PATTERN
  38.           SB7    X1
  39.           ZR     B7,STC2     IF NO ARGUMENTS
  40.  
  41. *         PROCESS SIGN ARGUMENT.
  42.  
  43.           SA1    ARGR
  44.           ZR     X1,STC2     IF BLANK
  45.           SA2    STCA-2
  46.           SB2    X1-1R+      CHECK SEPARATOR
  47.           NG     B2,STC1     IF NOT *+*
  48.           GT     B2,B1,STC1  IF NOT *-*
  49.           SA1    A1+B1       NEXT ARGUMENT
  50.           SX5    B2          SET SIGN
  51.  
  52. *         PROCESS VALUE ARGUMENT.
  53.  
  54.  STC1     SA2    A2+2        NEXT OPTION
  55.           BX7    X1-X2
  56.           ZR     X2,STC4     IF END OF OPTIONS
  57.           NZ     X7,STC1     IF NO MATCH
  58.           LX5    59          SET SIGN
  59.           SA2    A2+B1       SET VALUE
  60.           AX5    60
  61.           BX0    X2-X5       SAVE SETCORE VALUE
  62.  
  63. *         MOVE PRESET PROGRAM.
  64.  
  65.  STC2     SB2    PMLL
  66.  STC3     SA1    PML+B2
  67.           SB2    B2-B1
  68.           LX7    X1
  69.           SA7    B2+1
  70.           PL     B2,STC3     IF NOT END OF MOVE
  71.           BX6    X0          SET VALUE
  72.           LX7    X0
  73.           SA4    PMLA
  74.           SB3    A0-PMLL-2   SET WORD COUNT
  75.           SB2    B1+B1
  76.           SA6    A0-B1
  77.           SA7    A6-B1
  78.           JP     PML2        ENTER PRESET LOOP
  79.  
  80. *         PROCESS ARGUMENT ERROR.
  81.  
  82.  STC4     MESSAGE (=C* ILLEGAL ARGUMENT.*)
  83.           ABORT
  84.           SPACE  4
  85. **        TABLE OF SETCORE OPTIONS.
  86. *
  87. *         WORD 1 = OPTION.
  88. *         WORD 2 = VALUE.
  89.  
  90.  
  91.  STCA     CON    0LZERO,0
  92.           CON    0L0,0
  93.           CON    0LINDEF,1777BS48
  94.           CON    0LINF,3777BS48
  95.           CON    0           END OF TABLE
  96.  PML      SPACE  4
  97. **        PRESET MEMORY LOOP.
  98.  
  99.  
  100.  PML      BSS    0
  101.           LOC    0
  102.           CON    0
  103.  PML1     CON    0
  104.  
  105. *         NEXT THREE INSTRUCTIONS ARE LEFT IN RA+2.
  106.  
  107.  PML1.1   SA7    B1          END PROGRAM
  108.           SA6    A6+B1       PRESET (5)
  109.           JP     PML1        WAIT MONITOR
  110.  
  111.  PML2     SA6    A6-B2       PRESET UPPER CORE
  112.           SA7    A7-B2
  113.           SB3    B3-2
  114.           NZ     B3,PML2     IF UPPER MEMORY NOT PRESET
  115.           SA6    B2+B1       PRESET (3)
  116.           BX7    X4
  117.           SB6    B1
  118.           SA6    A6+B1       PRESET (4)
  119.           EQ     PML1.1      COMPLETE PROGRAM IN WORD 2
  120.  
  121.  
  122.           LOC    *O
  123.  PMLL     EQU    *-PML
  124.  
  125. *         (RA+1) END MONITOR CALL.
  126.  
  127.  PMLA     VFD    30/0LEND
  128.           EQ     PML1
  129.           SPACE  4
  130. **        COMMON DECKS.
  131.  
  132.  
  133. *CALL     COMCSYS
  134.           SPACE  4
  135.           END
cdc/nos2.source/opl871/setcore.txt · Last modified: 2023/08/05 17:24 by Site Administrator