ibm:vm370-lib:cms:dmsor3.assemble_src
Table of Contents
DMSOR3 Source
References
- Fixes Applied : 0
- This Source Date : Tuesday, December 12, 1978
- Last Fix ID : [Unmodified]
Source Listing
- DMSOR3.ASSEMBLE.txt
- OR3 TITLE 'DMSOR3 (CMS) VM/370 - RELEASE 6' 00001000
- SPACE 2 00002000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00003000
- *. * 00004000
- * MODULE NAME: * 00005000
- * DMSOR3 * 00006000
- * * 00007000
- * FUNCTION: * 00008000
- * THE FUNCTION OF DMSOR3 IS TO RELOCATE ALL DTF TABLE * 00009000
- * ADDRESS CONSTANTS FROM THE ASSEMBLED ADDRESSES TO * 00010000
- * EXECUTABLE STORAGE ADDRESSES. THIS IS ACCOMPLISHED BY * 00011000
- * SUBTRACTING FROM THE BAL ADDRESS PROVIDED BY THE * 00012000
- * OPENR MACRO IN REGISTER 0 A FOUR BYTE ASSEMBLED * 00013000
- * ADDRESS CONSTANT OF THE BAL ADDRESS. ANY DIFFERENCE * 00014000
- * INDICATES THAT THE PROGRAM HAS BEEN RELOCATED. * 00015000
- * RELOCATION IS PERFORMED FOR UNIT RECORD DTFS. * 00016000
- * * 00017000
- * ATTRIBUTES: * 00018000
- * DISCONTIGUOUS SHARED SEGMENT * 00019000
- * REENTRANT * 00020000
- * * 00021000
- * ENTRY POINTS: * 00022000
- * DMSOR3 * 00023000
- * * 00024000
- * ENTRY CONDITIONS: * 00025000
- * DMSOR3 IS INVOKED IN RESPONSE TO AN SVC 2 (FETCH) * 00026000
- * FROM DMSOR1. AT ENTRY TO DMSOR3, R0 POINTS TO A * 00027000
- * LIST OF DTF TABLE ADDRESSES. * 00028000
- * * 00029000
- * EXIT CONDITIONS: * 00030000
- * * 00031000
- * NORMAL EXITS: * 00032000
- * SVC 2 TO $$BOPEN TO OPEN THE DTFS * 00033000
- * AFTER THE ADCONS HAVE BEEN MODIFIED. * 00034000
- * * 00035000
- * SVC 2 TO $$BOPNR2 TO OPE DTFCP/DTFDI DTFS. * 00036000
- * * 00037000
- * ABNORMAL EXITS: * 00038000
- * NONE * 00039000
- * * 00040000
- * ERROR MESSAGES ISSUED BY THIS PROGRAM: * 00041000
- * NONE * 00042000
- * * 00043000
- * CALLS TO OTHER ROUTINES: * 00044000
- * DMSBOP (SVC 2) * 00045000
- * DMSOR2 (SVC 2) TO MODIFY DTFCP/DTFDI ADCONS * 00046000
- * * 00047000
- * EXTERNAL REFERENCES: * 00048000
- * REGEQU * 00049000
- * * 00050000
- * CALLED BY: * 00051000
- * INVOKED IN RESPONSE TO SVC 2 (FETCH FOR $$BOPNR3 FROM * 00052000
- * DMSOR1) * 00053000
- * * 00054000
- * TABLES AND WORK AREAS: * 00055000
- * ADCON TABLE - A TABLE CONSISTING OF INDIVIDUAL TABLES * 00056000
- * USED TO MODIFY DIFFERENT DTF TYPES. EACH* 00057000
- * HAS A UNIQUE NAME TO IDENTIFY IT. * 00058000
- * EACH TABLE HAS THE FOLLOWING LAYOUT: * 00059000
- * * 00060000
- * BYTE 1 CONTAINS THE COUNT OF ADCONS * 00061000
- * TO BE MODIFIED. * 00062000
- * * 00063000
- * BYTE 2 CONTAINS THE BYTE COUNT FROM * 00064000
- * THE LOGIC MODULE ADDRESS TO * 00065000
- * THE FIRST ADCON. * 00066000
- * * 00067000
- * SUBSEQUENT BYTES CONTAIN THE BYTE * 00068000
- * COUNT NEEDED TO ADDRESS THE NEXT * 00069000
- * ADCON. * 00070000
- * * 00071000
- * REGISTER USAGE: * 00072000
- * * 00073000
- * TABLEREG - 0 TABLE PARAMETER - INPUT * 00074000
- * BASEREG - 3 DTF TABLE ADDRESS * 00075000
- * MODREG - 4 DTF TABLE ADDRESS CONSTANT DISP. TABLE* 00076000
- * ADDRREG - 5 ADDRESS CONSTANT RELOCATE REGISTER * 00077000
- * COUNTREG - 6 COUNT OF DTF ADCONS TO BE CHANGED * 00078000
- * LINKREG - 7 LINK REGISTER TO ADDRESS MOD. RTN. * 00079000
- * TYPEREG - 8 USED TO DETERMINE DTF TYPE * 00080000
- * DTFREG - 9 DTF TYPE TABLE * 00081000
- * CCWREG - 10 POINTER TO START OF EACH DTF TABLE * 00082000
- * WORKREG1 - 11 TABLE PARAMETER WORK REGISTER * 00083000
- * R12 - BASE REGISTER * 00084000
- * RELOCREG - 13 RELOCATION FACTOR * 00085000
- * R14 - UNUSED * 00086000
- * R15 - UNUSED * 00087000
- * * 00088000
- * OPERATION: * 00089000
- * DMSOR3 PERFORMS THE FOLLOWING FUNCTIONS: * 00090000
- * 1. DETERMINES IF RELOCATION IS RE- * 00091000
- * QUIRED. IF NOT EXIT IS MADE TO * 00092000
- * $$BOPEN TO OPEN THE FILE. * 00093000
- * * 00094000
- * 2. DETERMINES WHAT DTF TYPE IS THE * 00095000
- * OBJECT OF THE OPENR MACRO. * 00096000
- * * 00097000
- * MODIFIES THE ADCONS IN THE * 00098000
- * UNIT RECORD DTFS. * 00099000
- * * 00100000
- * 3. AN SVC 2 (FETCH) FOR DMSOR2 IS * 00101000
- * ISSUED FOR DTFCP OR DTFDI DTFS. * 00102000
- * * 00103000
- * 3. A CHECK IS MADE TO SEE IF MORE * 00104000
- * FILES REMAIN TO BE OPENED. IF * 00105000
- * SO, ADDRESS MODIFICATION IS PER-* 00106000
- * FORMED ON THOSE DTFS AND THEN AN* 00107000
- * SVC 2 IS ISSUED TO FETCH $$BOPEN* 00108000
- *. TO PERFORM THE ACTUAL OPEN. * 00109000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00110000
- DMSOR3 CSECT @V305066 00111000
- TABLEREG EQU 0 POINTER TO TABLE SUPPLIED BY OPENR MACRO @V305066 00112000
- GR1 EQU 1 WORK REGISTER @V305066 00113000
- GR2 EQU 2 WORK REGISTER @V305066 00114000
- TYPEREG EQU 2 @V305066 00115000
- BASEREG EQU 3 CONTAINS ADDRESS OF THE ACTIVE DTF TABLE @V305066 00116000
- MODREG EQU 4 CONTAINS ADDR. OF DTF DISP. TABLE @V305066 00117000
- ADDRREG EQU 5 REG. USED TO RELOC. ADDRESS CONSTANTS @V305066 00118000
- COUNTREG EQU 6 CONTAINS COUNT OF ADDRESSES TO BE MODIFIED @V305066 00119000
- LINKREG EQU 7 LINK REGISTER @V305066 00120000
- LINKREG2 EQU 8 INTERNAL BRANCH REGISTER @V305066 00121000
- DTFREG EQU 9 DTF TYPE TABLE @V305066 00122000
- CCBREG EQU 10 POINT TO DTFDA BUILDING ROUTINE @V305066 00123000
- WORKREG1 EQU 11 POINTER TO DTF TABLE LIST @V305066 00124000
- RELOCREG EQU 13 REGISTER CONTAINS THE RELOCATION FACTOR @V305066 00125000
- GRD EQU 15 WORK REG - VALIDATE DTF ADDRESS @V305066 00126000
- RGE EQU 14 WORK REGISTER @V305066 00127000
- CCWREG EQU CCBREG @V305066 00128000
- DC CL8'$$BOPNR3' @V305066 00129000
- BALR R12,0 ESTABLISH ADDRESSABILITY @V305066 00130000
- USING *,R12 @V305066 00131000
- EJECT 00132000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00133000
- * THE ADDRESS OF THE DTF TABLE ADDRESSES IS PASSED IN REGISTER 0. * 00134000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00135000
- SPACE 2 00136000
- LR WORKREG1,TABLEREG PTR TO DTF TABLE ADDRESSES @V305066 00137000
- NEXT L CCWREG,0(WORKREG1) PT CCWREG TO BEG. OF TABLE @V305066 00138000
- LA BASEREG,16(CCWREG) INCREM INTO DTF @V305066 00139000
- TM 0(BASEREG),OPEN IS OPEN BIT ON ? @V305066 00140000
- BO RETURN YES,RETURN @V305066 00141000
- OI 0(BASEREG),OPEN SET OPEN BIT ON @V305066 00142000
- LA LINKREG2,MODEXIT LOAD BRANCH REGISTER @V305066 00143000
- EJECT 00144000
- *********************************************************************** 00145000
- * D T F T A B L E D E C O D E * 00146000
- * * 00147000
- * EACH DTF TYPE HAS IN ITS TABLE A UNIQUE CODE LOCATED IN DE MAL * 00148000
- * BYTE 20. THIS CODE IS USE TO DETERMINE WHICH DTF TYPE IS TO BE * 00149000
- * RELOCATED. * 00150000
- * SOME EXITS FROM THIS DECODE ARE TO ROUTINES THAT FURTHER DECODE THE * 00151000
- * DTF TYPE. * 00152000
- * AFTER THE DTF TYPE IS ESTABLISHED EXITS TO THE ADDRESS MODIFICATION * 00153000
- * SUBROUTINE ARE IN ONE OF TWO FORMS. * 00154000
- * THE FIRST FORM IS A BRANCH INSTRUCTION. THIS WILL CAUSE THE ADDRESS* 00155000
- * MODIFICATION SUBROUTINE TO EXIT TO THE ENDING ROUTINE. THE ENDING * 00156000
- * ROUTINE WILL DETERMINE IF ADDITIONAL DTF TABLES NEED MODIFICATION. * 00157000
- * THE SECOND FORM IS A BRANCH AND LINK. THIS WILL CAUSE THE ADDRESS * 00158000
- * MODIFICATION SUBROUTINE TO RETURN TO THE NEXT SEQUENTIAL INSTRUCTION* 00159000
- * THIS IS NEEDED BECAUSE OF ADDITIONAL CHECKS WITHIN THE TABLE TO * 00160000
- * DETERMINE IF FURTHER ADDRESS MODIFICATION IS NEEDED. FOLLOWING THE * 00161000
- * LAST BAL WILL BE A BRANCH TO THE ENDING ROUTINE. * 00162000
- *********************************************************************** 00163000
- SPACE 2 00164000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00165000
- * UNIT RECORD * 00166000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00167000
- SPACE 2 00168000
- UNITREC1 CLI 4(BASEREG),DTFCN DTFTYPE = DTFCN/DTFCD? @V305066 00169000
- LA MODREG,READER ADDR. OF DTFCD - RDR TABLE @V305066 00170000
- BNL CNDTF BRANCH IF NOT DTFCD-READER @V305066 00171000
- BAL LINKREG,MODLOOP BR TO MAKE ADD MODIFICATION @V305066 00172000
- TM 16(CCWREG),ERROPT TEST FOR ERROPT @V305066 00173000
- BZ UPTOASF NO, BRANCH @V305066 00174000
- CLI 52(CCWREG),BRINST TEST FOR BRANCH INST. @V305066 00175000
- BE UPTOASF YES, BRANCH @V305066 00176000
- LA MODREG,READOPT ADCON TABLE @V305066 00177000
- BAL LINKREG,MODLOOP BR TO MAKE ADD MODIFICATION @V305066 00178000
- B ASFRED @V305066 00179000
- UPTOASF LA BASEREG,20(BASEREG) UPDATE POINTER @V305066 00180000
- ASFRED TM 16(CCWREG),ASSOC ASSOCIATED FILES? @V305066 00181000
- BZ RETURN NO, BRANCH TO RETURN @V305066 00182000
- LA MODREG,READASF ADCON TABLE @V305066 00183000
- BR LINKREG2 DTFCD-READER @V305066 00184000
- CNDTF LA MODREG,CONSOLE LOAD ADDRESS OF DTFCN TABLE @V305066 00185000
- * BCR 8,LINKREG2 BRANCH IF DTFCN 00186000
- BC 7,NOTCON SKP NEXT INST IF NOT CON @V305066 00187000
- CLI 5(BASEREG),PUTR DTFCN WITH PUTR @V305066 00188000
- BCR 7,LINKREG2 NO, GO TO NORMAL CONSOL @V305066 00189000
- LA MODREG,CONSOL1 CONSOL WITH PUTR @V305066 00190000
- BCR 15,LINKREG2 @V305066 00191000
- NOTCON EQU * @V305066 00192000
- CLI 4(BASEREG),DTFCD DTF TYPE FOR DTFCD - PUNCH @V305066 00193000
- LA MODREG,PUNCH ADDRESS OF DTFCD-PUNCH TAB @V305066 00194000
- BNE PRINT NOT DTFCD PUNCH @V305066 00195000
- TM 22(BASEREG),MFCM TEST MFCM/U @V305066 00196000
- BNZ PUNCHM YES, HANDLE MFCM/U PCH FILE @V305066 00197000
- BAL LINKREG,MODLOOP MODIFY DTFCD TABLE @V305066 00198000
- TM 21(CCWREG),CCW2 TEST FOR SEC CCW @V305066 00199000
- BCR 1,LINKREG2 YES, MODIFY SECOND CCW @V305066 00200000
- TM 44(CCWREG),CHAIN CCW-CHAIN (PUNCH INT.) @V305066 00201000
- BZ ASFPCH NO, BRANCH @V305066 00202000
- LA MODREG,PCHINTRP ADR OF DTFCD PUNCH INTRP @V305066 00203000
- BR LINKREG2 @V305066 00204000
- ASFPCH TM 16(CCWREG),ASSOC ASSOCIATED FILES @V305066 00205000
- BZ RETURN NO, BRANCH @V305066 00206000
- LA MODREG,PCHASF ADCON TABLE @V305066 00207000
- BR LINKREG2 @V305066 00208000
- PRINT CLI 4(BASEREG),DTFPR TEST IF DTFPR - PRINTER @V305066 00209000
- LA MODREG,PRINTER LOAD ADDRESS OF DTFPR TABLE @V305066 00210000
- BNE NOTFOUND BR IF NOT PRINTER @V305066 00211000
- TM 0(BASEREG),STLIST TEST IF STLIST SPECIFIED @V305066 00212000
- BNZ AERROPT YES, RELOCATE ADDRESS @V305066 00213000
- TM 28(BASEREG),X'40' TEST IF STLIST SPEC @V305066 00214000
- BCR 8,LINKREG2 BRANCH IF NO @V305066 00215000
- AERROPT LA MODREG,PRINTST YES, RELOC. CCW OR AERROPT @V305066 00216000
- BR LINKREG2 @V305066 00217000
- SPACE 2 00218000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00219000
- * MFCM/U PUNCH FILE 00220000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00221000
- SPACE 2 00222000
- PUNCHM LA MODREG,PCHASOC LOAD ADCON PUNCH ASOC. FILE @V305066 00223000
- TM 0(BASEREG),ASSOC2 TEST FOR ASSOCIATED FILES @V305066 00224000
- BCR 1,LINKREG2 YES,PROCESS RELOCATION @V305066 00225000
- LA MODREG,PCHMFC LOAD ADCON PUNCH FILE @V305066 00226000
- TM 0(BASEREG),PCHINT TEST PUNCH/INTERPRET FILE @V305066 00227000
- BCR 8,LINKREG2 NO, PROCESS RELOCATION @V305066 00228000
- LA MODREG,PCHINTU ADCON PCH.INTRPRT MFCU FI @V305066 00229000
- TM 22(BASEREG),MFCM2 TEST MFCM @V305066 00230000
- BCR 8,LINKREG2 NO, PROCASS RELOCATION @V305066 00231000
- LA MODREG,PCHINTM LOAD ADCON PCH.INTRPRT MFCM @V305066 00232000
- BR LINKREG2 PROCESS RELOCATION @V305066 00233000
- EJECT 00234000
- *********************************************************************** 00235000
- * E N D I N G R O U T I N E * 00236000
- * * 00237000
- * A CHECK IS MADE TO DETERMINE IF MORE DTF TABLES REQUIRE ADDRESS * 00238000
- * MODIFICATION. IF SO, RETURN IS MADE TO THE START OF THIS TRANSIENT. * 00239000
- * IF NOT, A SUPERVISOR CALL 2 IS MADE TO CALL IN THE OPEN TRANSIENT. * 00240000
- *********************************************************************** 00241000
- SPACE 2 00242000
- NOTFOUND LA R14,ONE NEC. TO CALL $$BOPNR2 @V305066 00243000
- NI 16(CCWREG),F7 TURN OFF RELOC. BIT @V305066 00244000
- RETURN LA WORKREG1,4(WORKREG1) BUMP TO NEXT DTF TABLE @V305066 00245000
- CLI 0(WORKREG1),ENDTAB END OF DTF TABLE? @V305066 00246000
- BNE NEXT NO, PROCESS NEXT TABLE @V305066 00247000
- EXIT LTR R14,R14 SEE IF CALL TO $$BOPNR2 @V305066 00248000
- BNZ CALLPHZ2 YES @V305066 00249000
- LA R1,BOPEN PREPARE TO FETCH $$BOPEN @V305066 00250000
- SVC SVC2 CALL IN OPEN MONITOR @V305066 00251000
- CALLPHZ2 LA R1,BOPNR2 PREPARE TO CALL $$BOPNR2 @V305066 00252000
- SVC SVC2 FETCH $$BOPNR2 @V305066 00253000
- *********************************************************************** 00254000
- * * 00255000
- * A D D R E S S M O D I F I C A T I O N S U B R O U T I N E * 00256000
- * * 00257000
- * BASEREG CONTAINS ADDRESS OF THE ADCON TO BE MODIFIED * 00258000
- * COUNTREG CONTAINS NUMBER OF ADDRESSES TO BE MODIFIED * 00259000
- * DTFREG CONTAINS THE DIFFERENCE FROM ONE ADDRESS TO NEXT ADDRESS * 00260000
- * RELOCREG CONTAINS THE RELOCATION FACTOR * 00261000
- * MODREG POINTS TO OR WITHIN DISPLACEMENT TABLE * 00262000
- * ADDRREG IS THE WORK REGISTER * 00263000
- * THE ORIGINAL CONTENTS OF MODREG POINTS TO THE START OF THE CURRENT * 00264000
- * ADCON TABLE. THE FIRST BYTE OF EACH TABLE CONTAINS THE COUNT OF * 00265000
- * ADDRESSES TO BE MODIFIED. THIS COUNT IS PLACED IN COUNTREG. THE * 00266000
- * SECOND BYTE IS THE DISPLACEMENT BYTE COUNT OF THE FIRST ADCON FROM * 00267000
- * THE LOGIC MODULE ADDRESS IN THE DTF TABLE. EACH TABLE BYTE THERE- * 00268000
- * AFTER IS THE BYTE COUNT BETWEEN SUBSEQUENT ADCONS. EACH BYTE COUNT* 00269000
- * IS ADDED TO BASEREG TO ADDRESS EACH ADCON. THE ADCON TO BE * 00270000
- * MODIFIED IS LOADED INTO ADDRREG. THE RELOCATION FACTOR IN RELOCREG * 00271000
- * IS ADDED TO THE ADCON WITH THE RESULTANT EXECUTABLE ADDRESS STORED * 00272000
- * BACK INTO THE ASSEMBLED ADCON LOCATION. * 00273000
- *********************************************************************** 00274000
- SPACE 2 00275000
- MODEXIT LA LINKREG,RETURN LAST MOD. TO TABLE ENTRY @V305066 00276000
- MODLOOP SR DTFREG,DTFREG CLEAR DISPLACEMENT REG @V305066 00277000
- SR COUNTREG,COUNTREG CLEAR BCT REG @V305066 00278000
- IC COUNTREG,0(MODREG) INSERT COUNT @V305066 00279000
- LR GR1,CCWREG PT TO BEG. OF DTF TABLE @V305066 00280000
- LR GR2,GR1 LOAD MAX ADDRESS REGISTER @V305066 00281000
- SR GRD,GRD @V305066 00282000
- VALIDATE IC GRD,0(COUNTREG,MODREG) INSERT ADDR DISP. @V305066 00283000
- AR GR2,GRD ADD TO START OF TABLE @V305066 00284000
- BCT COUNTREG,VALIDATE @V305066 00285000
- SVC SVC26 PERFORM ADDRESS VALIDATION @V305066 00286000
- IC COUNTREG,0(MODREG) RESTORE COUNT @V305066 00287000
- MODLOOP1 LA MODREG,1(MODREG) POINT TO DISPLACEMENT @V305066 00288000
- IC DTFREG,0(MODREG) INSERT DISPLACEMENT FACTOR @V305066 00289000
- AR BASEREG,DTFREG ADD DISPLACE TO BASE @V305066 00290000
- CLC 1(3,BASEREG),ZERO COMPARE ADDRESS TO 0 @V305066 00291000
- BE MODLOOP2 ZERO ADDRESS, BYPASS UPDATE @V305066 00292000
- BYPASS L ADDRREG,0(BASEREG) ADCON TO BE MODIFIED @V305066 00293000
- AR ADDRREG,RELOCREG ADD RELOCATION FACTOR @V305066 00294000
- ST ADDRREG,0(BASEREG) STORE RELOCATED ADCON @V305066 00295000
- MODLOOP2 BCT COUNTREG,MODLOOP1 RELOCATE NEXT ADDRESS @V305066 00296000
- LA MODREG,1(MODREG) ADD ONE TO PT TO NEXT TAB @V305066 00297000
- BR LINKREG RETURN TO ASKING ROUTINE @V305066 00298000
- EJECT 00299000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00300000
- * * 00301000
- * CONSTANTS * 00302000
- * * 00303000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00304000
- SPACE 2 00305000
- ZERO DC XL3'000000' @V305066 00306000
- BOPEN DC CL8'$$BOPEN' OPEN MONITOR @V305066 00307000
- BOPNR2 DC CL8'$$BOPNR2' CALL TO CONTINUE DTF RELOCATION @V305066 00308000
- EJECT 00309000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00310000
- * * 00311000
- * EQUATES * 00312000
- * * 00313000
- * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00314000
- SPACE 2 00315000
- DTFCN EQU X'03' DTFCN - CONSOLE @V305066 00316000
- OPEN EQU X'08' DTF OPEN INDICATOR @V305066 00317000
- ERROPT EQU X'40' ERROPT PARAMTER IN DTF @V305066 00318000
- BRINST EQU X'47' BRANCH INSTRUCTION @V305066 00319000
- ASSOC EQU X'07' ASSOC/FUNC PARAMETERS ON DTF @V305066 00320000
- PUTR EQU X'01' DTFCN WITH PUTR CAPABILITY @V305066 00321000
- DTFCD EQU X'04' DTFCD - PUNCH @V305066 00322000
- MFCM EQU X'18' MFCM/U @V305066 00323000
- CCW2 EQU X'01' SECOND CCW @V305066 00324000
- CHAIN EQU X'40' @V305066 00325000
- DTFPR EQU X'08' DTFPR - PRINTER @V305066 00326000
- STLIST EQU X'40' STLIST SPECIFIED ON DTF @V305066 00327000
- ASSOC2 EQU X'01' ASSOCIATED FILES @V305066 00328000
- PCHINT EQU X'04' PUNCH INTERPRET @V305066 00329000
- MFCM2 EQU X'08' MFCM @V305066 00330000
- ONE EQU 1 @V305066 00331000
- F7 EQU X'F7' @V305066 00332000
- ENDTAB EQU X'0A' END OF DTF TABLE @V305066 00333000
- SVC2 EQU 2 @V305066 00334000
- SVC26 EQU 26 @V305066 00335000
- EJECT 00336000
- *********************************************************************** 00337000
- * A D C O N T A B L E * 00338000
- * THE FOLLOWING TABLE CONSISTS OF INDIVIDUAL TABLES USED TO MODIFY * 00339000
- * DIFFERENT DTF TYPES. EACH INDIVIDUAL TABLE HAS A UNIQUE NAME TO * 00340000
- * IDENTIFY IT. * 00341000
- * THE TABLE LAYOUT IS AS FOLLOWS- * 00342000
- * BYTE 1 CONTAINS THE COUNT OF ADCONS TO BE MODIFIED. * 00343000
- * BYTE 2 CONTAINS THE BYTE COUNT FROM THE LOGIC MODULE ADDRESS TO * 00344000
- * THE FIRST ADCON * 00345000
- * SUBSEQUENT BYTES CONTAIN THE BYTE COUNT NEEDED TO ADDRESS THE NEXT * 00346000
- * ADCON. * 00347000
- *********************************************************************** 00348000
- SPACE 2 00349000
- COMBINED DC X'050808041418' CCW,INPUT,OUTPUT,EOF @V305066 00350000
- READER DC X'03080404' IO AREA2, EOF, CCW @V305066 00351000
- READOPT DC X'0114' ERROPT=NAME @V305066 00352000
- READASF DC X'0104' ASSOCIATED FN TO READ @V305066 00353000
- CONSOLE DC X'0108' CCW @V305066 00354000
- CONSOL1 DC X'03080804' CCW, IP AREA, OUT AREA @V305066 00355000
- PUNCH DC X'020810' IOAREA1, CCW1 @V305066 00356000
- PUNCH1 DC X'0108' CCW2 @V305066 00357000
- PCHINTRP DC X'020808' @V305066 00358000
- PCHASF DC X'0108' ASSOCIATED FN TO PUNCH @V305066 00359000
- PRINTER DC X'020810' IO AREA, CCW @V305066 00360000
- PRINTST DC X'03081008' @V305066 00361000
- READERM DC X'0408040408' MFCM/U READ FILE @V305066 00362000
- READASOC DC X'050804040820' MFCM/U READ ASOC FILE @V305066 00363000
- READERR DC X'05080404081C' MFCM/U READ ERROPT FILE @V305066 00364000
- READASER DC X'06080404081C04' MFCM/U ASSOC. READ FILE @V305066 00365000
- * WITH ERROPT=NAME 00366000
- PCHMFC DC X'03081010' MFCM/U PUNCH FILE @V305066 00367000
- PCHASOC DC X'0408101008' MFCM/U PUNCH ASOC FILE @V305066 00368000
- PCHINTU DC X'0408101008' MFCU PUNCH/INT FILE @V305066 00369000
- PCHINTM DC X'06081010080808' MFCM PUNCH/INTRPRT FILE @V305066 00370000
- PRMFCM DC X'050810080808' MFCM PRINT SIMPLE FILE @V305066 00371000
- PRASOCM DC X'0408100808' MFCM PRINT ASOC FILE @V305066 00372000
- PRMFCU DC X'020818' MFCU PRINT SIMPLE FILE @V305066 00373000
- PRASOCU DC X'03081008' MFCU PRINT ASOC FILE @V305066 00374000
- MICR DC X'14' @V305066 00375000
- DC X'2820040404040C0C0C1408080808080808080808' @V305066 00376000
- MICR1 DC X'02' @V305066 00377000
- DC X'0808' @V305066 00378000
- SIXTEEN DC H'16' @V305066 00379000
- EJECT 00380000
- REGEQU @V305066 00381000
- DMSOR3 CSECT @V305066 00382000
- LTORG @V305066 00383000
- END 00385000
ibm/vm370-lib/cms/dmsor3.assemble_src.txt · Last modified: 2023/08/06 13:35 by Site Administrator